Adhere to Arch package guidelines

- Add transitive dependencies
  Dependencies not directly used by gBar or packages assumed to be
  present (packages from base or make dependencies from base-devel, as they are requirements
  for Arch or the AUR respectively) are omitted.
- Remove unnecessary provides
- Put the license file in the correct folder

2 files changed, 28 insertions, 20 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 5aa743922931..d4871836ab7f 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,6 +1,6 @@
 pkgbase = gbar-git
 	pkgdesc = Blazingly fast status bar written with GTK
-	pkgver = r221.d3f46bc
+	pkgver = r237.535d02c
 	pkgrel = 1
 	url = https://github.com/scorpion-26/gBar
 	arch = x86_64
@@ -9,18 +9,22 @@ pkgbase = gbar-git
 	makedepends = git
 	makedepends = meson
 	makedepends = ninja
-	makedepends = gcc
-	makedepends = pkgconf
+	depends = cairo
+	depends = gdk-pixbuf2
+	depends = glib2
+	depends = gtk3
 	depends = gtk-layer-shell
-	depends = pulseaudio
 	depends = libdbusmenu-gtk3
-	depends = pamixer
+	depends = libpulse
 	depends = libsass
+	depends = pamixer
+	depends = pulseaudio
+	depends = wayland
 	optdepends = bluez-utils: Bluetooth support
+	optdepends = dbus: Tray and bluetooth support
 	optdepends = hyprland: Workspace widgets
 	optdepends = nvidia-utils: Nvidia GPU support
 	optdepends = pacman-contrib: Arch update checking
-	provides = gbar
 	source = gBar::git+https://github.com/scorpion-26/gBar
 	sha256sums = SKIP
 
diff --git a/PKGBUILD b/PKGBUILD
index dc90bbf93062..f4af5b2777b7 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,7 +2,7 @@
 
 _pkgname=gBar
 pkgname=gbar-git
-pkgver=r221.d3f46bc
+pkgver=r237.535d02c
 pkgrel=1
 # Architectures which are atleast confirmed to somewhat work.
 arch=('x86_64' 'aarch64')
@@ -10,13 +10,23 @@ pkgdesc='Blazingly fast status bar written with GTK'
 url='https://github.com/scorpion-26/gBar'
 source=("$_pkgname::git+$url")
 license=('MIT')
-depends=('gtk-layer-shell' 'pulseaudio' 'libdbusmenu-gtk3' 'pamixer' 'libsass')
+depends=('cairo'
+         'gdk-pixbuf2'
+         'glib2'
+         'gtk3'
+         'gtk-layer-shell'
+         'libdbusmenu-gtk3'
+         'libpulse'
+         'libsass'
+         'pamixer'
+         'pulseaudio'
+         'wayland')
 optdepends=('bluez-utils: Bluetooth support'
+            'dbus: Tray and bluetooth support'
             'hyprland: Workspace widgets'
             'nvidia-utils: Nvidia GPU support'
             'pacman-contrib: Arch update checking')
-makedepends=('git' 'meson' 'ninja' 'gcc' 'pkgconf')
-provides=('gbar')
+makedepends=('git' 'meson' 'ninja')
 sha256sums=('SKIP')
 
 pkgver() {
@@ -24,21 +34,15 @@ pkgver() {
     printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
 }
 
-# 'meson setup build' should only be called once, so call it here
-prepare() {
-    cd "$_pkgname"
-    git submodule update --init
-    meson setup build -Dbuildtype=release -Dprefix=/usr
-}
-
 build() {
     cd "$_pkgname"
-    ninja -C build
+    meson setup build -Dbuildtype=release -Dprefix=/usr
+    meson compile -C build
 }
 
 package() {
     cd "$_pkgname"
-    DESTDIR="$pkgdir" ninja -C build install
-    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/"$_pkgname"/LICENSE
+    meson install -C build --destdir "$pkgdir"
+    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
     # TODO: Install default config into /usr/share (not supported by gBar)
 }