Initial commit

2 files changed, 53 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..26a0a368d43c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = gifsicle-git
+	pkgdesc = Command-line tool for creating, editing, and getting information about GIF images and animations (git version)
+	pkgver = 1.93.r0.g416518e
+	pkgrel = 1
+	url = https://www.lcdf.org/gifsicle/
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = libx11
+	optdepends = libx11: for gifview tool
+	provides = gifsicle
+	conflicts = gifsicle
+	source = git+https://github.com/kohler/gifsicle.git
+	sha256sums = SKIP
+
+pkgname = gifsicle-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..db5f887b4597
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Daniel Bermond <dbermond@archlinux.org>
+
+pkgname=gifsicle-git
+pkgver=1.93.r0.g416518e
+pkgrel=1
+pkgdesc='Command-line tool for creating, editing, and getting information about GIF images and animations (git version)'
+arch=('x86_64')
+url='https://www.lcdf.org/gifsicle/'
+license=('GPL2')
+optdepends=('libx11: for gifview tool')
+makedepends=('git' 'libx11')
+provides=('gifsicle')
+conflicts=('gifsicle')
+source=('git+https://github.com/kohler/gifsicle.git')
+sha256sums=('SKIP')
+
+prepare() {
+    autoreconf -fi gifsicle
+}
+
+pkgver() {
+    git -C gifsicle describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
+}
+
+build() {
+    cd gifsicle
+    ./configure --prefix='/usr'
+    make
+}
+
+check() {
+    gifsicle/test/testie -p gifsicle/src gifsicle/test
+}
+
+package() {
+    make -C gifsicle DESTDIR="$pkgdir" install
+}