Initial commit

2 files changed, 74 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..322104963fe3
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,29 @@
+pkgbase = gnome-books-git
+	pkgdesc = Access and organize your e-books on GNOME
+	pkgver = 3.34.0+17+gebf83fde
+	pkgrel = 1
+	url = https://wiki.gnome.org/Apps/Books
+	arch = x86_64
+	groups = gnome
+	license = GPL
+	makedepends = gobject-introspection
+	makedepends = git
+	makedepends = meson
+	makedepends = yelp-tools
+	depends = evince
+	depends = gjs
+	depends = gtk3
+	depends = gnome-desktop
+	depends = tracker-miners
+	depends = webkit2gtk
+	depends = libgepub
+	depends = gnome-epub-thumbnailer
+	provides = gnome-books
+	conflicts = gnome-books
+	source = git+https://gitlab.gnome.org/GNOME/gnome-books.git
+	source = git+https://gitlab.gnome.org/GNOME/libgd.git
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = gnome-books-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..83859dde9fff
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+pkgname=gnome-books-git
+_pkgname=gnome-books
+pkgver=3.34.0+17+gebf83fde
+pkgrel=1
+pkgdesc="Access and organize your e-books on GNOME"
+url="https://wiki.gnome.org/Apps/Books"
+arch=(x86_64)
+license=(GPL)
+depends=('evince' 'gjs' 'gtk3' 'gnome-desktop' 'tracker-miners' 'webkit2gtk' 'libgepub'
+         'gnome-epub-thumbnailer')
+makedepends=('gobject-introspection' 'git' 'meson' 'yelp-tools')
+provides=('gnome-books')
+conflicts=('gnome-books')
+groups=('gnome')
+source=("git+https://gitlab.gnome.org/GNOME/gnome-books.git"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $_pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $_pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git submodule update
+}
+  
+
+build() {
+  arch-meson $_pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}