initial upload

3 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..177b22a0f95f
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = gog-surviving_mars
+	pkgdesc = Stake your claim on the Red Planet and build the first functioning human colonies on Mars!
+	pkgver = 1.5_fuglesang_1011166
+	pkgrel = 1
+	url = https://www.gog.com/en/game/surviving_mars
+	arch = x86_64
+	license = custom
+	noextract = surviving_mars_1_5_fuglesang_1011166_55908.sh
+	noextract = surviving_mars.desktop
+	options = !strip
+	source = surviving_mars_1_5_fuglesang_1011166_55908.sh::gog://surviving_mars_1_5_fuglesang_1011166_55908.sh
+	source = surviving_mars.desktop
+	sha256sums = 5f266336d76a639017dc1391459e4d85f679d08db79d80e74436ff843b1021d7
+	sha256sums = 31fbb9c2de56494bfcbee6b3c431c63f18093851ff33a65c0e0ed593622fa546
+
+pkgname = gog-surviving_mars
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..882ce5d97e66
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: kyndair <kyndair at gmail dot com>
+# Place the gog installation file in the same folder as this PKGBUILD
+pkgname=gog-surviving_mars
+_pkgname=surviving_mars
+_goggame=2129244347
+pkgver=1.5_fuglesang_1011166
+_pkgver=1_5_fuglesang_1011166
+_build=55908
+pkgrel=1
+pkgdesc="Stake your claim on the Red Planet and build the first functioning human colonies on Mars!"
+arch=('x86_64')
+url="https://www.gog.com/en/game/surviving_mars"
+license=('custom')
+source=("${_pkgname}_${_pkgver}_${_build}.sh::gog://${_pkgname}_${_pkgver}_${_build}.sh"
+        "${_pkgname}.desktop")
+# don't download anything automatically
+DLAGENTS+=("gog::/usr/bin/perl -E print\(\"${RED}\"\ .\ substr\(\"%u\",\ 6\)\ .\ \"\ not\ found.\ \ Check\ the\ PKGBUILD\ for\ further\ information.${ALL_OFF}\\\\n\"\)\;\ exit\ 1")
+sha256sums=('5f266336d76a639017dc1391459e4d85f679d08db79d80e74436ff843b1021d7'
+            '31fbb9c2de56494bfcbee6b3c431c63f18093851ff33a65c0e0ed593622fa546')
+noextract=("${_pkgname}_${_pkgver}_${_build}.sh"
+        "${_pkgname}.desktop")
+options=("!strip")
+
+prepare() {
+    chmod +x ${_pkgname}_${_pkgver}_${_build}.sh
+    ./${_pkgname}_${_pkgver}_${_build}.sh -- --silent --destination="${srcdir}"
+}
+
+package() {
+    # install launcher
+    install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+    # install game icon
+    install -Dm644 "${srcdir}/support/icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
+    # install game documents
+    install -Dm644 "${srcdir}/docs/End User License Agreement.txt" "${pkgdir}/usr/share/doc/${_pkgname}/EULA"
+    install -Dm644 "${srcdir}/docs/installer_readme.txt" "${pkgdir}/usr/share/doc/${_pkgname}/installer.readme"
+    # install game data, executable and link in /usr/bin
+    find "${srcdir}/game" -type d -exec chmod 755 {} +
+    find "${srcdir}/game" -type f -exec chmod 644 {} +
+    mkdir -p "${pkgdir}/opt/${_pkgname}"
+    mv "${srcdir}/game/"* "${pkgdir}/opt/${_pkgname}"
+    chmod 755 "${pkgdir}/opt/${_pkgname}/MarsGOG"
+}
diff --git a/surviving_mars.desktop b/surviving_mars.desktop
new file mode 100644
index 000000000000..db61dadb9dbb
--- /dev/null
+++ b/surviving_mars.desktop
@@ -0,0 +1,10 @@
+[Desktop Entry]

+Name=Surviving Mars

+Exec=/opt/surviving_mars/MarsGOG

+Path=/opt/surviving_mars

+Icon=surviving_mars.png

+Terminal=false

+Type=Application

+X-DCOP-ServiceType=Multi

+X-KDE-StartupNotify=true

+Categories=Game;