Initial upload: groom-git r1.365ba93-2

2 files changed, 58 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..2f654adab93c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = groom-git
+	pkgdesc = groom is a self-hosted HTTPS reverse-proxy written in Go. Its an alternative to ngrok.
+	pkgver = r1.365ba93
+	pkgrel = 2
+	url = https://github.com/pyke369/groom
+	arch = x86_64
+	license = MIT
+	makedepends = go
+	makedepends = git
+	depends = glibc
+	provides = groom
+	source = groom::git+https://github.com/pyke369/groom.git
+	sha256sums = SKIP
+
+pkgname = groom-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6f310d485e1c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Cyrinux <pkgbuilds AT levis DOT name>
+
+pkgname=groom-git
+_pkgname=${pkgname%-git}
+pkgver=r1.365ba93
+pkgrel=2
+pkgdesc='groom is a self-hosted HTTPS reverse-proxy written in Go. Its an alternative to ngrok.'
+arch=('x86_64')
+url="https://github.com/pyke369/${_pkgname}"
+license=('MIT')
+depends=('glibc')
+makedepends=('go' 'git')
+provides=("${_pkgname}")
+source=("${_pkgname}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${_pkgname}"
+    (
+        set -o pipefail
+        git describe --long 2> /dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+    )
+}
+
+build() {
+    cd "${srcdir}/${_pkgname}"
+    export CGO_CPPFLAGS="${CPPFLAGS}"
+    export CGO_CFLAGS="${CFLAGS}"
+    export CGO_CXXFLAGS="${CXXFLAGS}"
+    export CGO_LDFLAGS="${LDFLAGS}"
+    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+    go build -o groom
+}
+
+package() {
+    install -D -m755 "${srcdir}/${_pkgname}/groom" "$pkgdir"/usr/bin/groom
+    install -d -m755 "${pkgdir}/usr/share/doc/${_pkgname}"
+    cp -r "${srcdir}/${_pkgname}/conf" "${pkgdir}/usr/share/doc/${_pkgname}/conf"
+    install -d "${pkgdir}/usr/share/licenses/${_pkgname}"
+    install -m644 "${srcdir}/${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/"
+}