Hopefully I didn't forget any dependencies

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..26400cb953b6
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = gswww-git
+	pkgdesc = A Graphical Solution to your Wayland Wallpaper Woes
+	pkgver = r33.5d7aa2d
+	pkgrel = 1
+	url = https://github.com/Ph1lll/Gswww
+	arch = x86_64
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	makedepends = cargo
+	depends = gcc-libs
+	depends = swww
+	depends = gtk4
+	optdepends = webp-pixbuf-loader: Render .webp images
+	provides = gswww
+	conflicts = gswww
+	options = !lto
+	source = gswww::git+https://github.com/Ph1lll/Gswww.git
+	sha256sums = SKIP
+
+pkgname = gswww-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..889c2908e3f3
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Phillip Davies (ph1lll) <philliptdavies@gmail.com>
+pkgname=gswww-git
+pkgver=r33.5d7aa2d
+pkgrel=1
+pkgdesc="A Graphical Solution to your Wayland Wallpaper Woes"
+arch=('x86_64' 'aarch64')
+url="https://github.com/Ph1lll/Gswww"
+license=('GPL3')
+depends=('gcc-libs' 'swww' 'gtk4')
+makedepends=('git' 'cargo')
+optdepends=('webp-pixbuf-loader: Render .webp images')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+options=(!lto)
+source=('gswww::git+https://github.com/Ph1lll/Gswww.git')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/gswww"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/gswww"
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$srcdir/gswww"
+	export RUSTUP_TOOLCHAIN=stable
+	cargo build --release --frozen
+}
+
+package() {
+	cd "$srcdir/gswww"
+
+	install -Dm755 target/release/gswww -t "$pkgdir/usr/bin/"
+	install -Dm644 assets/intergration/Gswww.png -t "$pkgdir/usr/share/pixmaps/"
+	install -Dm644 assets/intergration/Gswww.desktop -t "$pkgdir/usr/share/applications"
+}