newpkg: hisat2-git 2.2.1.r8.g49aa20c-1

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..644d8acb7f45
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = hisat2-git
+	pkgdesc = A fast and sensitive alignment program for mapping sequencing reads
+	pkgver = 2.2.1.r8.g49aa20c
+	pkgrel = 1
+	url = https://daehwankimlab.github.io/hisat2/
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = cmake
+	depends = glibc
+	optdepends = perl
+	optdepends = python
+	provides = hisat2
+	conflicts = hisat2
+	options = staticlibs
+	source = git+https://github.com/DaehwanKimLab/hisat2.git
+	sha256sums = SKIP
+
+pkgname = hisat2-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..51c22cd2d5e0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=hisat2-git
+pkgver=2.2.1.r8.g49aa20c
+pkgrel=1
+pkgdesc="A fast and sensitive alignment program for mapping sequencing reads"
+arch=('x86_64')
+url="https://daehwankimlab.github.io/hisat2/"
+license=('GPL')
+depends=('glibc')
+makedepends=('git' 'cmake')
+optdepends=('perl' 'python')
+provides=('hisat2')
+conflicts=('hisat2')
+options=('staticlibs')
+source=("git+https://github.com/DaehwanKimLab/hisat2.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "hisat2"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "hisat2"
+
+  cmake \
+    -B "_build" \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX="/usr" \
+    ./
+  make -C "_build"
+}
+
+package() {
+  cd "hisat2"
+
+  install -Dm755 hisat2{,-*} -t "$pkgdir/usr/bin"
+  install -Dm755 "_build"/hisat2-* -t "$pkgdir/usr/bin"
+
+  install -Dm644 "_build/libhisat2lib.a" -t "$pkgdir/usr/lib"
+  install -Dm755 "_build/libhisat2lib.so" -t "$pkgdir/usr/lib"
+
+  install -Dm644 {MANUAL.markdown,README.md,TUTORIAL} -t "$pkgdir/usr/share/doc/hisat2"
+}