Make it so.

3 files changed, 66 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..f42c30d9ba7a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = hyprshade-git
+	pkgdesc = Quickly swap between screen shaders in Hyprland
+	pkgver = r36.a128afb
+	pkgrel = 1
+	url = https://github.com/loqusion/hyprshade
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	depends = hyprland
+	depends = python-more-itertools
+	depends = python-typer
+	depends = util-linux
+	provides = hyprshade
+	conflicts = hyprshade
+	source = git+https://github.com/loqusion/hyprshade.git
+	sha512sums = SKIP
+
+pkgname = hyprshade-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..18fa11c30e3a
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*.zst
+hyprshade
+pkg
+src
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1df81e5c0bdd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: John Bernard <loqusion@gmail.com>
+_pkgname=hyprshade
+pkgname=${_pkgname}-git
+pkgver=r36.a128afb
+pkgrel=1
+pkgdesc="Quickly swap between screen shaders in Hyprland"
+arch=('any')
+url="https://github.com/loqusion/hyprshade"
+license=('MIT')
+_py_deps=(
+	more-itertools
+	typer
+)
+depends=(
+	hyprland
+	"${_py_deps[@]/#/python-}"
+	util-linux
+)
+makedepends=(git python-{build,installer})
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=(git+https://github.com/loqusion/${_pkgname}.git)
+sha512sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+	{
+		set -o pipefail
+		git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+			printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	}
+}
+
+build() {
+	cd "$_pkgname"
+	python -m build -wn
+}
+
+package() {
+	cd "$_pkgname"
+	PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer -d "$pkgdir" dist/*.whl
+}