Add package 'ir-lv2-git', renamed from 'lv2-ir-git

4 files changed, 80 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..fa5fc3b9a253
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = ir-lv2-git
+	pkgdesc = Real-time signal convolver esp. suited for impulse response reverb effects
+	pkgver = 1.3.2.r17.af1f8ab
+	pkgrel = 1
+	url = http://factorial.hu/plugins/lv2/ir
+	changelog = ChangeLog
+	arch = i686
+	arch = x86_64
+	groups = lv2-plugins
+	license = GPL
+	makedepends = lv2
+	depends = gtk2>=2.16
+	depends = libsamplerate
+	depends = zita-convolver
+	provides = ir.lv2
+	provides = ir-lv2
+	provides = lv2-ir-git
+	conflicts = ir.lv2
+	conflicts = ir-lv2
+	conflicts = lv2-ir
+	conflicts = lv2-ir-git
+	source = ir-lv2::git+https://github.com/Anchakor/ir.lv2.git
+	md5sums = SKIP
+
+pkgname = ir-lv2-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..ee6c513540ad
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,6 @@
+ir-lv2/
+src/
+pkg/
+ir-lv2-git-*.tar.xz
+ir-lv2-git-*.src.tar.gz
+.AURINFO
diff --git a/ChangeLog b/ChangeLog
new file mode 100644
index 000000000000..63d3ee089aa2
--- /dev/null
+++ b/ChangeLog
@@ -0,0 +1,4 @@
+2015-08-22 Christopher Arndt <chris@chrisarndt.de>
+
+	* 1.3.2.r17.af1f8ab-1 :
+	Renamed from package 'lv2-ir-git'
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6620eb6d7694
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
+# Contributor: Jiří Procházka <ojirio@gmail.com>
+
+_pkgname=ir-lv2
+pkgname="${_pkgname}-git"
+pkgver=1.3.2.r17.af1f8ab
+pkgrel=1
+pkgdesc="Real-time signal convolver esp. suited for impulse response reverb effects"
+arch=('i686' 'x86_64')
+url="http://factorial.hu/plugins/lv2/ir"
+license=('GPL')
+depends=('gtk2>=2.16' 'libsamplerate' 'zita-convolver')
+provides=('ir.lv2' "${_pkgname}" 'lv2-ir-git')
+conflicts=('ir.lv2' "${_pkgname}" 'lv2-ir' 'lv2-ir-git')
+groups=('lv2-plugins')
+makedepends=('lv2')
+source=("${_pkgname}::git+https://github.com/Anchakor/ir.lv2.git")
+md5sums=('SKIP')
+changelog=ChangeLog
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+
+  version="$(awk -F'"' '/S1 "version/ {print $2}' ir_gui.cc)"
+  echo ${version#version}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+
+  make $MAKEFLAGS
+  make convert4chan $MAKEFLAGS
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}"
+
+  make PREFIX="$pkgdir/usr" install
+  install -Dm755 convert4chan "$pkgdir/usr/bin/convert4chan"
+  install -Dm644 README "${pkgdir}"/usr/share/doc/$pkgname/README
+}
+
+# vim:set ts=2 sw=2 et: