Initial import

2 files changed, 60 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1ee9502888fa
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = karlender-git
+	pkgdesc = An apative GTK-4 calendar app.
+	pkgver = r100.5844090
+	pkgrel = 1
+	url = https://gitlab.com/loers/karlender
+	arch = x86_64
+	arch = aarch64
+	license = GPL3
+	checkdepends = appstream-glib
+	makedepends = git
+	makedepends = cargo
+	depends = libadwaita
+	depends = libnotify
+	provides = karlender
+	conflicts = karlender
+	source = git+https://gitlab.com/loers/karlender.git
+	b2sums = SKIP
+
+pkgname = karlender-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100755
index 000000000000..581dd0968cc6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Igor Dyatlov <dyatlov.igor@protonmail.com>
+
+pkgname=karlender-git
+pkgver=r100.5844090
+pkgrel=1
+pkgdesc="An apative GTK-4 calendar app."
+arch=('x86_64' 'aarch64')
+url="https://gitlab.com/loers/karlender"
+license=('GPL3')
+depends=('libadwaita' 'libnotify')
+makedepends=('git' 'cargo')
+checkdepends=('appstream-glib')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=(git+$url.git)
+b2sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cd "${pkgname%-git}"
+
+  cargo build --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+
+  sed -i 's|ROOT=/app|ROOT=/usr|g' target/gra-gen/Makefile
+
+  make -C target/gra-gen ROOT="$pkgdir/usr" install
+  make -C target/gra-gen ROOT="$pkgdir/usr" install-gsettings
+
+  rm "$pkgdir/usr/share/glib-2.0/schemas/gschemas.compiled"
+}