Initial upload: kbs2-git 0.1.5.r0.gd7a70e1-1

2 files changed, 56 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7442264a257b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = kbs2-git
+	pkgdesc = A secret manager backed by age (git)
+	pkgver = 0.1.5.r0.gd7a70e1
+	pkgrel = 1
+	url = https://github.com/woodruffw/kbs2
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = python
+	makedepends = git
+	depends = libx11
+	provides = kbs2
+	conflicts = kbs2
+	source = git+https://github.com/woodruffw/kbs2
+	sha512sums = SKIP
+
+pkgname = kbs2-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..24350c1da707
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=kbs2-git
+pkgver=0.1.5.r0.gd7a70e1
+pkgrel=1
+pkgdesc="A secret manager backed by age (git)"
+arch=('x86_64')
+url="https://github.com/woodruffw/kbs2"
+license=('MIT')
+depends=('libx11')
+makedepends=('cargo' 'python' 'git')
+conflicts=("${pkgname%-git}")
+provides=("${pkgname%-git}")
+source=("git+${url}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --locked --all-features
+}
+
+check() {
+  cd "${pkgname%-git}"
+  cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
+}