initial upload

2 files changed, 50 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b5a015f39f79
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = kdevelop-python-git
+	pkgdesc = Python language and documentation plugin for KDevelop, git version
+	pkgver = 5.6.2.r3.gf8b381b6
+	pkgrel = 1
+	url = http://www.kdevelop.org/
+	arch = x86_64
+	license = GPL
+	makedepends = extra-cmake-modules
+	makedepends = git
+	depends = kdevelop
+	depends = python
+	optdepends = python-pycodestyle: for Python style checking
+	provides = kdevelop-python
+	conflicts = kdevelop-python
+	source = git+https://invent.kde.org/kdevelop/kdev-python.git#branch=5.6
+	sha256sums = SKIP
+
+pkgname = kdevelop-python-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5852022d294a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Michal Wojdyla <micwoj9292 at gmail dot com>
+
+pkgname=kdevelop-python-git
+pkgver=5.6.2.r3.gf8b381b6
+pkgrel=1
+pkgdesc="Python language and documentation plugin for KDevelop, git version"
+arch=(x86_64)
+url="http://www.kdevelop.org/"
+license=(GPL)
+depends=(kdevelop python)
+makedepends=(extra-cmake-modules git)
+optdepends=('python-pycodestyle: for Python style checking')
+provides=('kdevelop-python')
+conflicts=('kdevelop-python')
+source=("git+https://invent.kde.org/kdevelop/kdev-python.git#branch=5.6") # currently master branch fails
+sha256sums=('SKIP')
+
+pkgver() {
+  cd kdev-python
+  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cmake -B build -S kdev-python \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}