chore: publish 3.5.5.20231213

3 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a891d82f801d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,14 @@
+pkgbase = kdrive-appimage
+	pkgdesc = kDrive allows you to collaborate, store and share your data securely via your web browser, your mobile, your tablet or your computer.
+	pkgver = 3.5.5.20231213
+	pkgrel = 1
+	url = https://github.com/user/repo/
+	arch = x86_64
+	license = custom:Unlicense
+	depends = zlib
+	noextract = kdrive-appimage-3.5.5.20231213.AppImage
+	options = !strip
+	source_x86_64 = kdrive-appimage-3.5.5.20231213.AppImage::https://download.storage.infomaniak.com/drive/desktopclient/kDrive-3.5.5.20231213-amd64.AppImage
+	sha256sums_x86_64 = 0d69e1d9fe592aafb39e6829c67f382c6f6c665dc57433b1809abeff4e92e17a
+
+pkgname = kdrive-appimage
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..b69136cbd040
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+pkg
+src
+*.zst
+*.AppImage
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..90f6d9db756f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Based on the template from https://daveparrish.net/posts/2019-11-16-Better-AppImage-PKGBUILD-template.html
+# Maintainer: Robin Bühler <r plus aur at obin dot ch>
+
+_pkgname=kdrive
+_originalpkgname=kDrive
+
+pkgname="${_pkgname}"-appimage
+pkgver=3.5.5.20231213
+pkgrel=1
+pkgdesc="kDrive allows you to collaborate, store and share your data securely via your web browser, your mobile, your tablet or your computer."
+arch=('x86_64')
+url="https://www.infomaniak.com/en/apps/download-kdrive"
+license=('custom:Unlicense')
+depends=('zlib')
+options=(!strip)
+_appimage="${pkgname}-${pkgver}.AppImage"
+source_x86_64=("${_appimage}::https://download.storage.infomaniak.com/drive/desktopclient/kDrive-${pkgver}-amd64.AppImage")
+noextract=("${_appimage}")
+sha256sums_x86_64=('0d69e1d9fe592aafb39e6829c67f382c6f6c665dc57433b1809abeff4e92e17a')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|"\
+        "squashfs-root/${_originalpkgname}_client.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_originalpkgname}_client.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+}