Recover package

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..46e5d8c6a54a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = kpackage-git
+	pkgdesc = Framework that lets applications manage user installable packages of non-binary assets
+	pkgver = r198.09e0ac7
+	pkgrel = 1
+	url = https://projects.kde.org/projects/frameworks/kpackage
+	arch = i686
+	arch = x86_64
+	groups = kf5
+	license = LGPL
+	makedepends = extra-cmake-modules
+	makedepends = git
+	makedepends = qt5-tools
+	makedepends = python
+	makedepends = kdoctools
+	depends = qt5-base
+	depends = karchive-git
+	depends = ki18n-git
+	depends = kcoreaddons-git
+	depends = kconfig-git
+	provides = kpackage
+	conflicts = kpackage
+	source = git://anongit.kde.org/kpackage.git
+	md5sums = SKIP
+
+pkgname = kpackage-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e1431f12613d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+# Contributor: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
+
+pkgname=kpackage-git
+pkgver=r198.09e0ac7
+pkgrel=1
+pkgdesc="Framework that lets applications manage user installable packages of non-binary assets"
+arch=(i686 x86_64)
+url="https://projects.kde.org/projects/frameworks/kpackage"
+license=(LGPL)
+depends=(qt5-base karchive-git ki18n-git kcoreaddons-git kconfig-git)
+makedepends=(extra-cmake-modules git qt5-tools python kdoctools)
+groups=(kf5)
+conflicts=(kpackage)
+provides=(kpackage)
+source=("git://anongit.kde.org/kpackage.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd kpackage
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../kpackage \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIB_INSTALL_DIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}