First PKGBUILD

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..956df358ea77
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,29 @@
+pkgbase = kpipewire-git
+	pkgdesc = KDE Plasma Kpipewire
+	pkgver = 5.28.80_r205.g67f8d36
+	pkgrel = 1
+	url = https://community.kde.org/Frameworks
+	arch = x86_64
+	groups = kf5-git
+	license = LGPL
+	makedepends = git
+	makedepends = extra-cmake-modules-git
+	makedepends = doxygen
+	makedepends = qt5-tools
+	makedepends = qt5-wayland
+	makedepends = kwayland-git
+	makedepends = plasma-wayland-protocols-git
+	depends = kcoreaddons-git
+	depends = kconfig-git
+	depends = ki18n-git
+	depends = kcodecs-git
+	depends = iso-codes
+	depends = pipewire
+	depends = ffmpeg
+	depends = libepoxy
+	provides = kpipewire
+	conflicts = kpipewire
+	source = git+https://github.com/KDE/kpipewire.git
+	sha256sums = SKIP
+
+pkgname = kpipewire-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..336c8cca44db
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer:  Oleg Tsvetkov <oleg@tsvetkov.dev>
+# PKGBUILD is based on one from Chaotic AUR GitHub and was published here since the actual kpipewire-git wasn't in AUR already but is required by many packages in plasma. Be free
+# (all respective contributors apply herein)
+# Contributor: João Figueiredo & chaotic-aur <islandc0der@chaotic.cx>
+# Contributor: Felix Golatofski <contact@xdfr.de>
+# Contributor: Antonio Rojas <arojas@archlinux.org>
+# Contributor: Henri Chain <henri@henricha.in>
+
+pkgname=kpipewire-git
+pkgver=5.28.80_r205.g67f8d36
+pkgrel=1
+pkgdesc="KDE Plasma Kpipewire"
+arch=($CARCH)
+url="https://community.kde.org/Frameworks"
+license=(LGPL)
+depends=(kcoreaddons-git kconfig-git ki18n-git kcodecs-git iso-codes pipewire ffmpeg libepoxy)
+makedepends=(git extra-cmake-modules-git doxygen qt5-tools qt5-wayland kwayland-git plasma-wayland-protocols-git)
+conflicts=(${pkgname%-git})
+provides=(${pkgname%-git})
+groups=(kf5-git)
+source=("git+https://github.com/KDE/${pkgname%-git}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname%-git}
+  _ver="$(grep -m1 'set(PROJECT_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
+  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cmake -B build -S ${pkgname%-git} \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}