Add lethelp-certbot-git (aka letshelp-letsencrypt)

Add according package for the cerbot, previously letsencrypt, helper
script.

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..356709a2d74d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = letshelp-certbot-git
+	pkgdesc = Let's help Certbot client
+	pkgver = 0.5.0.r57.g86e09d5
+	pkgrel = 1
+	url = https://github.com/letsencrypt/letsencrypt
+	arch = any
+	license = Apache
+	makedepends = git
+	depends = python2-setuptools
+	depends = python2-mock
+	provides = letshelp-certbot
+	conflicts = letshelp-certbot
+	source = letsencrypt::git+https://github.com/letsencrypt/letsencrypt
+	md5sums = SKIP
+
+pkgname = letshelp-certbot-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e9852ca2e137
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+#  Maintainer: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgname=letshelp-certbot-git
+_reponame="letsencrypt"
+pkgver=0.5.0.r57.g86e09d5
+pkgrel=1
+pkgdesc="Let's help Certbot client"
+arch=('any')
+license=('Apache')
+url="https://github.com/letsencrypt/${_reponame}"
+depends=('python2-setuptools' 'python2-mock')
+makedepends=('git')
+provides=("letshelp-certbot")
+conflicts=("letshelp-certbot")
+source=("${_reponame}"::"git+https://github.com/letsencrypt/letsencrypt")
+md5sums=('SKIP')
+
+pkgver() {
+	cd "${srcdir}/${_reponame}"
+	( set -o pipefail
+	git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
+	|| printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+build() {
+	cd "${srcdir}/${_reponame}/letshelp-certbot"
+	python2 setup.py clean
+	rm -rf build dist
+	python2 setup.py build
+}
+
+package() {
+	cd "${srcdir}/${_reponame}/letshelp-certbot"
+	python2 setup.py install --root="${pkgdir}" --optimize=1
+}