Bump to 0.18.5+14+g9980655

New package

2 files changed, 70 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a302c78d4241
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = lib32-libsecret
+	pkgdesc = Library for storing and retrieving passwords and other secrets
+	pkgver = 0.18.5+14+g9980655
+	pkgrel = 1
+	url = https://wiki.gnome.org/Projects/Libsecret
+	arch = x86_64
+	license = LGPL
+	checkdepends = python-dbus
+	checkdepends = dbus-glib
+	checkdepends = python-gobject
+	checkdepends = gjs
+	makedepends = intltool
+	makedepends = gobject-introspection
+	makedepends = vala
+	makedepends = git
+	depends = lib32-glib2
+	depends = lib32-libgcrypt
+	depends = libsecret=0.18.5+14+g9980655
+	optdepends = gnome-keyring: key storage service (or use any other service implementing org.freedesktop.secrets)
+	source = git+https://git.gnome.org/browse/libsecret#commit=998065599c66055dcffa1ef1ddebb947ccd68248
+	sha256sums = SKIP
+
+pkgname = lib32-libsecret
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..02e54100e664
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+_pkgbasename=libsecret
+pkgname=lib32-$_pkgbasename
+pkgver=0.18.5+14+g9980655
+pkgrel=1
+pkgdesc="Library for storing and retrieving passwords and other secrets"
+arch=(x86_64)
+license=(LGPL)
+url="https://wiki.gnome.org/Projects/Libsecret"
+depends=(lib32-glib2 lib32-libgcrypt $_pkgbasename=$pkgver)
+checkdepends=(python-dbus dbus-glib python-gobject gjs)
+makedepends=(intltool gobject-introspection vala git)
+optdepends=('gnome-keyring: key storage service (or use any other service implementing org.freedesktop.secrets)')
+_commit=998065599c66055dcffa1ef1ddebb947ccd68248  # master
+source=("git+https://git.gnome.org/browse/libsecret#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $_pkgbasename
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $_pkgbasename
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $_pkgbasename
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-static --disable-gtk-doc --libdir=/usr/lib32
+  make
+}
+
+check() {
+  cd $_pkgbasename
+  dbus-run-session make -k check 
+}
+
+package() {
+  cd $_pkgbasename
+  make DESTDIR="$pkgdir" install
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+}