lib32-sdl-git 1.2.15.r336.08d4c52c-1

2 files changed, 77 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5dfa75453d3b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,27 @@
+pkgbase = lib32-sdl-git
+	pkgdesc = A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (32-bit)
+	pkgver = 1.2.15.r336.08d4c52c
+	pkgrel = 1
+	url = https://www.libsdl.org
+	arch = x86_64
+	license = LGPL
+	makedepends = lib32-alsa-lib
+	makedepends = lib32-mesa
+	makedepends = lib32-libpulse
+	makedepends = lib32-glu
+	makedepends = gcc-multilib
+	makedepends = git
+	depends = lib32-libxext
+	depends = lib32-libxrender
+	depends = lib32-libx11
+	depends = sdl
+	optdepends = lib32-alsa-lib: ALSA audio driver
+	optdepends = lib32-libpulse: PulseAudio audio driver
+	provides = lib32-sdl=1.2.15.r336.08d4c52c
+	conflicts = lib32-sdl
+	options = staticlibs
+	source = git+https://github.com/libsdl-org/SDL-1.2.git
+	md5sums = SKIP
+
+pkgname = lib32-sdl-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6a6d6f605271
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Rafał Kozdrój <kozeid2+aur@gmail.com>
+# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Allan McRae <allan@archlinux.org>
+# Contributor: dorphell <dorphell@archlinux.org>
+
+_pkgbasename=sdl
+_pkgname=lib32-$_pkgbasename
+pkgname=$_pkgname-git
+pkgver=1.2.15.r336.08d4c52c
+pkgrel=1
+pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (32-bit)"
+arch=('x86_64')
+url="https://www.libsdl.org"
+license=('LGPL')
+depends=('lib32-libxext' 'lib32-libxrender' 'lib32-libx11' $_pkgbasename)
+makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' 'lib32-glu' 'gcc-multilib' 'git')
+optdepends=('lib32-alsa-lib: ALSA audio driver'
+            'lib32-libpulse: PulseAudio audio driver')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+options=('staticlibs')
+source=("git+https://github.com/libsdl-org/SDL-1.2.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "SDL-1.2"
+  git describe --long --tags | sed 's/^release-//;s/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd "SDL-1.2"
+  ./autogen.sh
+  ./configure --prefix=/usr --disable-nasm --enable-alsa \
+              --with-x --disable-rpath --disable-static --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd "SDL-1.2"
+  make DESTDIR="$pkgdir/" install
+
+  rm -rf "$pkgdir"/usr/{include,share}
+
+  cd "$pkgdir/usr/bin"
+  mv sdl-config sdl-config-32
+}