First version of the libfprint-tod variant - build from source

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..2279c0398b5d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,29 @@
+pkgbase = libfprint-tod-git
+	pkgdesc = Library for fingerprint readers - TOD version
+	pkgver = 1.90.2+tod1
+	pkgrel = 1
+	url = https://fprint.freedesktop.org/
+	arch = x86_64
+	groups = fprint
+	license = LGPL
+	checkdepends = python
+	checkdepends = python-cairo
+	checkdepends = python-gobject
+	checkdepends = umockdev>=0.13.2
+	makedepends = git
+	makedepends = gobject-introspection
+	makedepends = gtk-doc
+	makedepends = meson>=0.49.0
+	depends = libgusb>=0.3.0
+	depends = nss
+	depends = pixman
+	provides = libfprint
+	provides = libfprint-tod
+	provides = libfprint-2.so
+	provides = libfprint-2-tod.so
+	conflicts = libfprint
+	source = git+https://gitlab.freedesktop.org/3v1n0/libfprint.git#branch=tod
+	sha256sums = SKIP
+
+pkgname = libfprint-tod-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a00a4bc2baa7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Pablo Arteaga <pablo at pabloarteaga (dot) com>
+#
+# This is a modified version of the libfprint-git PKGBUILD file on the AUR
+
+pkgname=libfprint-tod-git
+_pkgdirname=libfprint
+pkgver=1.90.2+tod1
+pkgrel=1
+pkgdesc="Library for fingerprint readers - TOD version"
+arch=(x86_64)
+url="https://fprint.freedesktop.org/"
+license=(LGPL)
+depends=('libgusb>=0.3.0' nss pixman)
+makedepends=(git gobject-introspection gtk-doc 'meson>=0.49.0')
+checkdepends=(python python-cairo python-gobject 'umockdev>=0.13.2')
+optdepends=()
+# Provide libfprint for compatibility with fprintd and also provide libfprint-tod for tod-style-only drivers
+provides=(libfprint libfprint-tod libfprint-2.so libfprint-2-tod.so)
+conflicts=(libfprint)
+groups=(fprint)
+source=("git+https://gitlab.freedesktop.org/3v1n0/libfprint.git#branch=tod")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $_pkgdirname
+  git describe --tags | sed 's/^V_\|^v//;s/_/./g;s/-/.r/;s/-/./'
+}
+
+build() {
+  arch-meson $_pkgdirname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}