[add] liblcf-git

k, update easyrpg-player-git to use it

2 files changed, 58 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..597969f080ca
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = liblcf-git
+	pkgdesc = Library to handle RPG Maker 2000/2003 and EasyRPG projects (development version)
+	pkgver = 0.1.2.r94.gc02ba45
+	pkgrel = 1
+	url = https://easy-rpg.org/
+	arch = i686
+	arch = x86_64
+	license = MIT
+	makedepends = boost
+	makedepends = git
+	makedepends = expat
+	provides = liblcf
+	conflicts = liblcf
+	options = staticlibs
+	source = liblcf::git+https://github.com/EasyRPG/liblcf.git
+	md5sums = SKIP
+
+pkgname = liblcf-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..223727409b27
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: carstene1ns <url/mail: arch carsten-teibes de>
+
+pkgname=liblcf-git
+pkgver=0.1.2.r94.gc02ba45
+pkgrel=1
+pkgdesc="Library to handle RPG Maker 2000/2003 and EasyRPG projects (development version)"
+arch=('i686' 'x86_64')
+url="https://easy-rpg.org/"
+license=('MIT')
+conflicts=('liblcf')
+provides=('liblcf')
+makedepends=('boost' 'git' 'expat')
+source=(liblcf::"git+https://github.com/EasyRPG/liblcf.git")
+md5sums=('SKIP')
+options=(staticlibs)
+
+pkgver() {
+  cd liblcf
+  git describe --long | sed 's/-/.r/;s/-/./'
+}
+
+build () {
+  cd liblcf
+
+  autoreconf -i
+  ./configure --prefix=/usr
+  make
+}
+
+package () {
+  cd liblcf
+
+  make DESTDIR="$pkgdir/" install
+  # move files to right location, if needed (temporary fix)
+  install -d "$pkgdir"/usr/include/liblcf
+  mv "$pkgdir"/usr/include/*.h "$pkgdir"/usr/include/liblcf
+  # license
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}