newpkg: libnetfilter_conntrack-git 1.0.6.r6.g2edc7cc-1

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ddb236fc5900
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = libnetfilter_conntrack-git
+	pkgdesc = Library providing access to the in-kernel connection tracking state table
+	pkgver = 1.0.6.r6.g2edc7cc
+	pkgrel = 1
+	url = https://netfilter.org/projects/libnetfilter_conntrack/index.html
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = libnfnetlink
+	depends = libmnl
+	provides = libnetfilter_conntrack
+	conflicts = libnetfilter_conntrack
+	source = git://git.netfilter.org/libnetfilter_conntrack
+	sha256sums = SKIP
+
+pkgname = libnetfilter_conntrack-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6674246b09b6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=libnetfilter_conntrack-git
+pkgver=1.0.6.r6.g2edc7cc
+pkgrel=1
+pkgdesc="Library providing access to the in-kernel connection tracking state table"
+arch=('i686' 'x86_64')
+url="https://netfilter.org/projects/libnetfilter_conntrack/index.html"
+license=('GPL')
+depends=('libnfnetlink' 'libmnl')
+makedepends=('git')
+provides=('libnetfilter_conntrack')
+conflicts=('libnetfilter_conntrack')
+source=("git://git.netfilter.org/libnetfilter_conntrack")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "libnetfilter_conntrack"
+
+  git describe --long --tags | sed 's/^libnetfilter_conntrack-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "libnetfilter_conntrack"
+
+  ./autogen.sh
+  ./configure --prefix="/usr"
+  make
+}
+
+package() {
+  cd "libnetfilter_conntrack"
+
+  make DESTDIR="$pkgdir" install
+}