newpkg: libnetfilter_queue-git 1.0.3.r0.g601abd1-1

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..d4554afaa10b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = libnetfilter_queue-git
+	pkgdesc = Library providing an API to packets that have been queued by the kernel packet filter
+	pkgver = 1.0.3.r0.g601abd1
+	pkgrel = 1
+	url = https://netfilter.org/projects/libnetfilter_queue/index.html
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = libnfnetlink
+	depends = libmnl
+	provides = libnetfilter_queue
+	conflicts = libnetfilter_queue
+	source = git://git.netfilter.org/libnetfilter_queue
+	sha256sums = SKIP
+
+pkgname = libnetfilter_queue-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bbe40cae0bad
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=libnetfilter_queue-git
+pkgver=1.0.3.r0.g601abd1
+pkgrel=1
+pkgdesc="Library providing an API to packets that have been queued by the kernel packet filter"
+arch=('i686' 'x86_64')
+url="https://netfilter.org/projects/libnetfilter_queue/index.html"
+license=('GPL')
+depends=('libnfnetlink' 'libmnl')
+makedepends=('git')
+provides=('libnetfilter_queue')
+conflicts=('libnetfilter_queue')
+source=("git://git.netfilter.org/libnetfilter_queue")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "libnetfilter_queue"
+
+  git describe --long --tags | sed 's/^libnetfilter_queue-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "libnetfilter_queue"
+
+  ./autogen.sh
+  ./configure --prefix="/usr"
+  make
+}
+
+package() {
+  cd "libnetfilter_queue"
+
+  make DESTDIR="$pkgdir" install
+}