Added extra archs & PKGBUILD cleanup

2 files changed, 22 insertions, 36 deletions

diff --git a/.SRCINFO b/.SRCINFO
index e8e7a66433fb..a02164132724 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,14 +1,18 @@
 pkgbase = libtd-git
 	pkgdesc = TDLib (Telegram Database library) is a cross-platform library for building Telegram clients (Git)
-	pkgver = 1.6.0.r756.gf45d80fe
-	pkgrel = 2
+	pkgver = 1.7.0.r747.gb342ec33
+	pkgrel = 1
 	url = https://core.telegram.org/tdlib
 	arch = x86_64
+	arch = arm
+	arch = armv7h
+	arch = armv6h
+	arch = aarch64
 	license = Boost
 	makedepends = git
-	makedepends = gcc>=4.9.2
+	makedepends = gcc
 	makedepends = make
-	makedepends = cmake>=3.0.2
+	makedepends = cmake
 	makedepends = gperf
 	makedepends = php
 	depends = openssl
diff --git a/PKGBUILD b/PKGBUILD
index c26850cf5188..31190d574d67 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,49 +1,31 @@
-# Maintainer: Felix Golatofski <contact@xdfr.de>
-# Contributor: Felix Serrano Blanco <felixseblanc@gmail.com>
+# Maintainer: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >
+# Previous Maintainer: Felix Golatofski <contact@xdfr.de>
+# Previous Contributor: Felix Serrano Blanco <felixseblanc@gmail.com>
 
-_pkgname=libtd
-pkgname=${_pkgname}-git
-pkgver=1.6.0.r756.gf45d80fe
-pkgrel=2
+pkgname=libtd-git
+pkgver=1.7.0.r747.gb342ec33
+pkgrel=1
 pkgdesc='TDLib (Telegram Database library) is a cross-platform library for building Telegram clients (Git)'
-arch=('x86_64')
+arch=('x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64')
 url='https://core.telegram.org/tdlib'
 license=('Boost')
-depends=(
-  'openssl'
-  'zlib'
-)
-makedepends=(
-  'git'
-  'gcc>=4.9.2'
-  'make'
-  'cmake>=3.0.2'
-  'gperf'
-  'php'
-)
+depends=('openssl' 'zlib')
+makedepends=('git' 'gcc' 'make' 'cmake' 'gperf' 'php')
 provides=('libtd')
 conflicts=('telegram-tdlib' 'libtd')
-source=("$_pkgname::git+https://github.com/tdlib/td.git")
+source=("${pkgname%-git}::git+https://github.com/tdlib/td.git")
 sha256sums=('SKIP')
 
 pkgver() {
-  cd "$srcdir/$_pkgname"
-  # cutting off 'v' prefix that presents in the git tag
+  cd "${pkgname%-git}"
   git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 build() {
-  cd "$srcdir/$_pkgname"
-  rm -rf build
-  mkdir build
-  cd build
-  CXXFLAGS=""
-  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX:PATH="$pkgdir/usr" ..
-  cmake --build .
+  cmake -B build -S "${pkgname%-git}" -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
+  cmake --build build --config Release
 }
 
 package() {
-  cd "$srcdir/$_pkgname/build"
-  mkdir -p "$pkgdir/usr"
-  cmake --build . --target install
+  DESTDIR="${pkgdir}" cmake --install build --config Release
 }