Initial commit

2 files changed, 55 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..724e946e3a2d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = libultrahdr-git
+	pkgdesc = Codec for the Ultra HDR format (git version)
+	pkgver = 1.0.0.r103.g74993de
+	pkgrel = 1
+	url = https://github.com/google/libultrahdr/
+	arch = x86_64
+	license = Apache-2.0
+	makedepends = git
+	makedepends = cmake
+	depends = gcc-libs
+	depends = libjpeg
+	provides = libultrahdr
+	conflicts = libultrahdr
+	source = git+https://github.com/google/libultrahdr.git
+	sha256sums = SKIP
+
+pkgname = libultrahdr-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ecbf2557290a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Daniel Bermond <dbermond@archlinux.org>
+
+pkgname=libultrahdr-git
+pkgver=1.0.0.r103.g74993de
+pkgrel=1
+pkgdesc='Codec for the Ultra HDR format (git version)'
+arch=('x86_64')
+url='https://github.com/google/libultrahdr/'
+license=('Apache-2.0')
+depends=('gcc-libs' 'libjpeg')
+makedepends=('git' 'cmake')
+provides=('libultrahdr')
+conflicts=('libultrahdr')
+source=('git+https://github.com/google/libultrahdr.git')
+sha256sums=('SKIP')
+
+pkgver() {
+    git -C libultrahdr describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
+}
+
+build() {
+    cmake -B build -S libultrahdr \
+        -G 'Unix Makefiles' \
+        -DCMAKE_BUILD_TYPE:STRING='None' \
+        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
+        -DUHDR_BUILD_TESTS:BOOL='ON' \
+        -Wno-dev
+    cmake --build build
+}
+
+check() {
+    ctest --test-dir build --output-on-failure
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+    install -D -m755 build/ultrahdr_app -t "${pkgdir}/usr/bin"
+}