init commit

3 files changed, 215 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4dbd85786af7
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,62 @@
+pkgbase = linux-aarch64-flippy-bin
+	pkgver = 6.0.7
+	pkgrel = 1
+	url = https://github.com/ophub/kernel
+	arch = aarch64
+	license = GPL2
+	noextract = boot-6.0.7-flippy-78+.tar.gz
+	noextract = dtb-allwinner-6.0.7-flippy-78+.tar.gz
+	noextract = dtb-amlogic-6.0.7-flippy-78+.tar.gz
+	noextract = dtb-rockchip-6.0.7-flippy-78+.tar.gz
+	noextract = header-6.0.7-flippy-78+.tar.gz
+	noextract = modules-6.0.7-flippy-78+.tar.gz
+	options = !strip
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/boot-6.0.7-flippy-78+.tar.gz
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/dtb-allwinner-6.0.7-flippy-78+.tar.gz
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/dtb-amlogic-6.0.7-flippy-78+.tar.gz
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/dtb-rockchip-6.0.7-flippy-78+.tar.gz
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/header-6.0.7-flippy-78+.tar.gz
+	source = https://github.com/ophub/kernel/raw/main/pub/stable/6.0.7/modules-6.0.7-flippy-78+.tar.gz
+	sha256sums = 4fdb7a91a6ea395beb02254352d259f578913f9610a1b40dc240c380bc5e4e64
+	sha256sums = 585e9c6055aeed4573c4cf59d9e769df206b7a79846866ab42ce2bb40d029095
+	sha256sums = 9f57c9fa29f32fc449f20e1f2548ee2049a0c7ef6bcb34fcf9ad61c4955dfba9
+	sha256sums = 14dca8da6a0cbef2a5e55af822ba3d7c738565fe42a61aa227086f9638385370
+	sha256sums = efd32c0b24d4fd88247cb17355c7ac35816be3bf14424ab50c64e1a07a7376d6
+	sha256sums = ef07fbfb56a8b0ee7214fef511d2a33656ab3748ea05230f770acb9116366c75
+
+pkgname = linux-aarch64-flippy-bin
+	pkgdesc = The Linux Kernel and module - flippy's AArch64-focused fork aiming to increase usability. Prebuilt by ophub.
+	depends = linux-aarch64-flippy-dtb
+	depends = coreutils
+	depends = initramfs
+	depends = kmod
+	optdepends = uboot-legacy-initrd-hooks: to generate uboot legacy initrd images
+	optdepends = linux-firmware-amlogic-ophub: Firmware for Amlogic SoCs
+	optdepends = wireless-regdb: to set the correct wireless channels of your country
+	optdepends = linux-aarch64-flippy-dtb-allwinner: DTBs for Allwinner SoCs
+	optdepends = linux-aarch64-flippy-dtb-amlogic: DTBs for Amlogic SoCs
+	optdepends = linux-aarch64-flippy-dtb-rockchip: DTBs for Rockchip SoCs
+	provides = linux-aarch64-flippy=6.0.7
+	conflicts = linux-aarch64-flippy
+	backup = etc/mkinitcpio.d/linux-aarch64-flippy.preset
+
+pkgname = linux-aarch64-flippy-bin-headers
+	pkgdesc = Header files and scripts for building modules for linux kernel - flippy's AArch64-focused fork aiming to increase usability. Prebuilt by ophub.
+
+pkgname = linux-aarch64-flippy-bin-dtb-allwinner
+	pkgdesc = DTB files for Allwinner SoCs for flippy's AArch64 kernel
+	provides = linux-aarch64-flippy-dtb=6.0.7
+	provides = linux-aarch64-flippy-dtb-allwinner=6.0.7
+	conflicts = linux-aarch64-flippy-dtb-allwinner
+
+pkgname = linux-aarch64-flippy-bin-dtb-amlogic
+	pkgdesc = DTB files for Amlogic SoCs for flippy's AArch64 kernel
+	provides = linux-aarch64-flippy-dtb=6.0.7
+	provides = linux-aarch64-flippy-dtb-amlogic=6.0.7
+	conflicts = linux-aarch64-flippy-dtb-amlogic
+
+pkgname = linux-aarch64-flippy-bin-dtb-rockchip
+	pkgdesc = DTB files for Rockchip SoCs for flippy's AArch64 kernel
+	provides = linux-aarch64-flippy-dtb=6.0.7
+	provides = linux-aarch64-flippy-dtb-rockchip=6.0.7
+	conflicts = linux-aarch64-flippy-dtb-rockchip
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f986c127d2a4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,139 @@
+# Maintainer: 7Ji <pugokughin@gmail.com>
+
+_desc="flippy's AArch64-focused fork aiming to increase usability. Prebuilt by ophub."
+_pkgver_main=6.0.7
+_pkgver_suffix=flippy-78+
+_pkgver_uname="${_pkgver_main}-${_pkgver_suffix}"
+_url_repo="https://github.com/ophub/kernel"
+_url_raw="${_url_repo}/raw/main/pub/stable/${_pkgver_main}"
+_pkgbase=linux-aarch64-flippy
+
+pkgbase="${_pkgbase}-bin"
+pkgname=(
+  "${pkgbase}"
+  "${pkgbase}-headers"
+  "${pkgbase}-dtb-allwinner"
+  "${pkgbase}-dtb-amlogic"
+  "${pkgbase}-dtb-rockchip"
+)
+pkgver="${_pkgver_main}"
+pkgrel=1
+arch=('aarch64')
+url="${_url_repo}"
+license=('GPL2')
+options=(!strip)
+source=(
+  "${_url_raw}/boot-${_pkgver_uname}.tar.gz"
+  "${_url_raw}/dtb-allwinner-${_pkgver_uname}.tar.gz"
+  "${_url_raw}/dtb-amlogic-${_pkgver_uname}.tar.gz"
+  "${_url_raw}/dtb-rockchip-${_pkgver_uname}.tar.gz"
+  "${_url_raw}/header-${_pkgver_uname}.tar.gz"
+  "${_url_raw}/modules-${_pkgver_uname}.tar.gz"
+)
+noextract=("${source[@]##*/}")
+sha256sums=(
+  '4fdb7a91a6ea395beb02254352d259f578913f9610a1b40dc240c380bc5e4e64'
+  '585e9c6055aeed4573c4cf59d9e769df206b7a79846866ab42ce2bb40d029095'
+  '9f57c9fa29f32fc449f20e1f2548ee2049a0c7ef6bcb34fcf9ad61c4955dfba9'
+  '14dca8da6a0cbef2a5e55af822ba3d7c738565fe42a61aa227086f9638385370'
+  'efd32c0b24d4fd88247cb17355c7ac35816be3bf14424ab50c64e1a07a7376d6'
+  'ef07fbfb56a8b0ee7214fef511d2a33656ab3748ea05230f770acb9116366c75'
+)
+
+_dtb_common_pkg="${_pkgbase}-dtb"
+
+package_linux-aarch64-flippy-bin() {
+  pkgdesc="The Linux Kernel and module - ${_desc}"
+  depends=(
+    "${_dtb_common_pkg}"
+    'coreutils'
+    'initramfs'
+    'kmod'
+  )
+  optdepends=(
+    'uboot-legacy-initrd-hooks: to generate uboot legacy initrd images'
+    'linux-firmware-amlogic-ophub: Firmware for Amlogic SoCs'
+    'wireless-regdb: to set the correct wireless channels of your country'
+    "${_pkgbase}-dtb-allwinner: DTBs for Allwinner SoCs"
+    "${_pkgbase}-dtb-amlogic: DTBs for Amlogic SoCs"
+    "${_pkgbase}-dtb-rockchip: DTBs for Rockchip SoCs"
+  )
+  provides=(
+    "${_pkgbase}=${pkgver}"
+  )
+  conflicts=(
+    "${_pkgbase}"
+  )
+  backup=(
+    "etc/mkinitcpio.d/${_pkgbase}.preset"
+  )
+
+  # Install modules
+  install -d -m 755 "${pkgdir}/usr/lib/modules"
+  tar -C "${pkgdir}/usr/lib/modules" -xvzf "${srcdir}/modules-${_pkgver_uname}.tar.gz"
+
+  # Install pkgbase
+  local _dir_module="${pkgdir}/usr/lib/modules/${_pkgver_uname}"
+    echo "${_pkgbase}" | install -D -m 644 /dev/stdin "${_dir_module}/pkgbase"
+
+  # Install kernel itself
+  local _vmlinuz="vmlinuz-${_pkgver_uname}"
+  tar -C "${_dir_module}" -xvzf "${srcdir}/boot-${_pkgver_uname}.tar.gz" "${_vmlinuz}"
+  mv -v "${_dir_module}/${_vmlinuz}" "${_dir_module}/vmlinuz"
+
+  # Remove non-standard folders
+  rm -f "${pkgdir}/usr/lib/modules/${_pkgver_uname}/"{build,source}
+
+  # install mkinitcpio preset file
+  sed "s|%PKGBASE%|${_pkgbase}|g" ../linux.preset |
+    install -Dm644 /dev/stdin "${pkgdir}/etc/mkinitcpio.d/${_pkgbase}.preset"
+}
+
+package_linux-aarch64-flippy-bin-headers() {
+  pkgdesc="Header files and scripts for building modules for linux kernel - ${_desc}"
+  install -d -m 755 "${pkgdir}/usr/lib/modules/${_pkgver_uname}/build"
+  tar -C "${pkgdir}/usr/lib/modules/${_pkgver_uname}/build" -xvzf "${srcdir}/header-${_pkgver_uname}.tar.gz"
+  install -d -m 755 "${pkgdir}/usr/src"
+  ln -sf "../lib/modules/${_pkgver_uname}/build" "${pkgdir}/usr/src/${_pkgbase}"
+}
+
+_dtb_common_provides="${_dtb_common_pkg}=${pkgver}"
+
+package_linux-aarch64-flippy-bin-dtb-allwinner() {
+  pkgdesc="DTB files for Allwinner SoCs for flippy's AArch64 kernel"
+  provides=(
+    "${_dtb_common_provides}"
+    "${_pkgbase}-dtb-allwinner=${pkgver}"
+  )
+  conflicts=(
+    "${_pkgbase}-dtb-allwinner"
+  )
+  install -d -m 755 "${pkgdir}/boot/dtbs/${_pkgbase}/allwinner"
+  tar -C "${pkgdir}/boot/dtbs/${_pkgbase}/allwinner" -xvzf "${srcdir}/dtb-allwinner-${_pkgver_uname}.tar.gz"
+}
+
+package_linux-aarch64-flippy-bin-dtb-amlogic() {
+  pkgdesc="DTB files for Amlogic SoCs for flippy's AArch64 kernel"
+  provides=(
+    "${_dtb_common_provides}"
+    "${_pkgbase}-dtb-amlogic=${pkgver}"
+  )
+  conflicts=(
+    "${_pkgbase}-dtb-amlogic"
+  )
+  install -d -m 755 "${pkgdir}/boot/dtbs/${_pkgbase}/amlogic"
+  tar -C "${pkgdir}/boot/dtbs/${_pkgbase}/amlogic" -xvzf "${srcdir}/dtb-amlogic-${_pkgver_uname}.tar.gz"
+}
+
+package_linux-aarch64-flippy-bin-dtb-rockchip() {
+  pkgdesc="DTB files for Rockchip SoCs for flippy's AArch64 kernel"
+  provides=(
+    "${_dtb_common_provides}"
+    "${_pkgbase}-dtb-rockchip=${pkgver}"
+  )
+  conflicts=(
+    "${_pkgbase}-dtb-rockchip"
+  )
+  install -d -m 755 "${pkgdir}/boot/dtbs/${_pkgbase}/rockchip"
+  tar -C "${pkgdir}/boot/dtbs/${_pkgbase}/rockchip" -xvzf "${srcdir}/dtb-rockchip-${_pkgver_uname}.tar.gz"
+}
\ No newline at end of file
diff --git a/linux.preset b/linux.preset
new file mode 100644
index 000000000000..53a108c35a79
--- /dev/null
+++ b/linux.preset
@@ -0,0 +1,14 @@
+# mkinitcpio preset file for the '%PKGBASE%' package
+
+ALL_config="/etc/mkinitcpio.conf"
+ALL_kver="/boot/vmlinuz-%PKGBASE%"
+
+PRESETS=('default' 'fallback')
+
+#default_config="/etc/mkinitcpio.conf"
+default_image="/boot/initramfs-%PKGBASE%.img"
+#default_options=""
+
+#fallback_config="/etc/mkinitcpio.conf"
+fallback_image="/boot/initramfs-%PKGBASE%-fallback.img"
+fallback_options="-S autodetect"
\ No newline at end of file