创建

Signed-off-by: 冯诚 <fengcheng@lidig.com>

1 files changed, 65 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7d66824f825b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Based off of: https://daveparrish.net/posts/2019-11-16-Better-AppImage-PKGBUILD-template.html
+# Maintainer: Pieter Verweij <git at pieterv24 dot dev>
+
+_pkgname=linuxqq
+_Pkgname=Linuxqq
+_disname=qq
+
+pkgname="${_pkgname}"-appimage
+pkgver=3.1.1_11223
+pkgrel=1
+pkgdesc="New Linux QQ based on Electron"
+arch=('x86_64' 'aarch64')
+url="https://im.qq.com/linuxqq/"
+license=('custom')
+options=(!strip)
+depends=('zlib' 'hicolor-icon-theme')
+provides=('qq' 'linuxqq')
+
+source_x86_64=("${_Pkgname}-${pkgver}-x86_64.AppImage::https://dldir1.qq.com/qqfile/qq/QQNT/2355235c/${_pkgname}_${pkgver//_/-}_x86_64.AppImage")
+source_aarch64=("${_Pkgname}-${pkgver}-aarch64.AppImage::https://dldir1.qq.com/qqfile/qq/QQNT/2355235c/${_pkgname}_${pkgver//_/-}_arm64.AppImage")
+sha256sums_x86_64=('27f15ae01973ef2216d84fa8755e949abc535fce11f5214e2f902c9027baeb0f')
+sha256sums_aarch64=('b2cc69ee832addc697d9dd08730cd97f0aa085060dcc419d4c08b656b19d5703')
+
+_appimage="${_Pkgname}-${pkgver}-${arch}.AppImage"
+noextract=("${_appimage}")
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i \
+        -e "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|" \
+        -e "s|Icon=.*|Icon=/usr/share/icons/${_pkgname}.png|" \
+        "squashfs-root/${_disname}.desktop"
+
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+    install -Dm644 "${srcdir}/squashfs-root/LICENSE.electron.txt" "${pkgdir}/opt/${pkgname}/LICENSE"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_disname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+    ln -s "$(realpath ${srcdir}/squashfs-root/${_disname}.png  --relative-to ${srcdir}/squashfs-root/usr/share/icons)"\
+        "${pkgdir}/usr/share/icons/${_pkgname}.png"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+
+    # Symlink license
+    install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}/"
+    ln -s "/opt/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}
\ No newline at end of file