init

3 files changed, 83 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9a9f6b5dd8e9
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = lite-xl-git
+	pkgdesc = A lightweight text editor written in Lua
+	pkgver = 1.16.9.r0.ge58d760
+	pkgrel = 1
+	url = https://github.com/franko/lite-xl-git
+	arch = x86_64
+	license = MIT
+	makedepends = meson>=0.58
+	makedepends = gendesk
+	depends = lua52
+	depends = sdl2
+	depends = freetype2
+	provides = lite-xl
+	conflicts = lite
+	conflicts = lite-xl
+	source = git+https://github.com/franko/lite-xl
+	source = lite-xl-git.svg.zip::https://github.com/rxi/lite/files/4716765/lite.svg.zip
+	sha256sums = SKIP
+	sha256sums = 504d2ccd74f1c5b631b5b83a4f4319c74edb705fc383b3058f4b2d9354093b53
+
+pkgname = lite-xl-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..1425c800285f
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,7 @@
+pkg/
+src/
+lite-xl/
+
+#
+lite-xl-git-*.tar.???
+lite-xl-git.svg.zip
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b8ee87d4aed2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Sergii Fesenko <sergii underscore f dot at outlook dot com>
+# PKGBUILD based on the one from https://aur.archlinux.org/packages/lite-xl
+
+pkgname=lite-xl-git
+_pkgname=lite-xl
+pkgver=1.16.9.r0.ge58d760
+pkgrel=1
+pkgdesc='A lightweight text editor written in Lua'
+arch=('x86_64')
+url="https://github.com/franko/$pkgname"
+license=('MIT')
+depends=('lua52' 'sdl2' 'freetype2')
+makedepends=('meson>=0.58' 'gendesk')
+conflicts=("lite" "lite-xl")
+provides=("$_pkgname")
+source=("git+https://github.com/franko/lite-xl"
+	# credits to 6r1d  for the svg icon
+	"$pkgname.svg.zip::https://github.com/rxi/lite/files/4716765/lite.svg.zip")
+sha256sums=('SKIP'
+            '504d2ccd74f1c5b631b5b83a4f4319c74edb705fc383b3058f4b2d9354093b53')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+  git describe --tags --long | sed 's/^v//; s/\([^-]*-g\)/r\1/; s/-/./g'
+}
+
+prepare() {
+  cd "$_pkgname"
+
+  # XDG desktop file
+  gendesk -n -f \
+          --pkgname "$_pkgname" \
+          --pkgdesc "$pkgdesc" \
+          --exec "lite %F" \
+          --name "Lite XL" \
+          --categories "Utility;TextEditor;Development" \
+          --mimetype "text/plain"
+}
+
+build() {
+  cd "$_pkgname"
+  arch-meson build --wrap-mode default
+  meson compile -C build
+}
+
+package() {
+  cd "$_pkgname"
+
+  DESTDIR="$pkgdir" meson install --skip-subprojects -C build
+
+  install -Dm 644 "../lite.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/${_pkgname}.svg"
+  install -Dm 644 "${_pkgname}.desktop" -t "$pkgdir/usr/share/applications"
+  install -Dm 644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
+}