Initial commit

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5e4921c16ed4
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,12 @@
+pkgbase = localsend-bin
+	pkgdesc = An open source cross-platform alternative to AirDrop
+	pkgver = 1.6.2
+	pkgrel = 1
+	url = https://github.com/localsend/localsend
+	arch = x86_64
+	license = MIT
+	options = !strip
+	source = https://github.com/localsend/localsend/releases/download/v1.6.2/LocalSend-1.6.2.AppImage
+	sha256sums = b50f10d1a1c85069c14f9a02a61d4b7ee32daef841c8af0b6d67520299bcb95b
+
+pkgname = localsend-bin
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2a1037629d5f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Nixuge
+
+pkgname=localsend-bin
+pkgver=1.6.2
+pkgrel=1
+pkgdesc='An open source cross-platform alternative to AirDrop '
+url=https://github.com/localsend/localsend
+arch=(x86_64)
+license=(MIT)
+options=(!strip)
+source=("https://github.com/localsend/localsend/releases/download/v${pkgver}/LocalSend-${pkgver}.AppImage")
+sha256sums=('b50f10d1a1c85069c14f9a02a61d4b7ee32daef841c8af0b6d67520299bcb95b')
+_appimage="LocalSend-${pkgver}.AppImage"
+_appimage_nover="localsend.AppImage"
+_pkgname="localsend"
+_pkgdesktop="org.localsend.localsend_app.desktop"
+
+
+prepare() {
+	chmod +x "${_appimage}"
+	./"${_appimage}" --appimage-extract
+}
+
+build() {
+	# Adjust .desktop so it will work outside of AppImage container
+	sed -i -E \
+		"s|Exec=localsend_app|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|" \
+		"squashfs-root/${_pkgdesktop}"
+	# Fix permissions; .AppImage permissions are 700 for all directories
+	chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+	# AppImage
+	install -Dm755 \
+		"${srcdir}/${_appimage}" \
+		"${pkgdir}/opt/${_pkgname}/${_appimage_nover}"
+
+	# Desktop file
+	install -Dm644 \
+		"${srcdir}/squashfs-root/${_pkgdesktop}" \
+		"${pkgdir}/usr/share/applications/${_pkgdesktop}"
+    
+	# Symlink executable
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -s \
+		"/opt/${_pkgname}/${_appimage_nover}" \
+		"${pkgdir}/usr/bin/${_pkgname}"
+}