low-memory-monitor-git r20.bd5d587

Initial PKGBUILD!

2 files changed, 53 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..8da66953385b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = low-memory-monitor-git
+	pkgdesc = Early boot daemon monitoring memory pressure information and invokes OOM if needed
+	pkgver = r20.bd5d587
+	pkgrel = 1
+	url = https://gitlab.freedesktop.org/hadess/low-memory-monitor
+	arch = x86_64
+	license = GPL3
+	makedepends = meson
+	makedepends = git
+	depends = systemd
+	provides = low-memory-monitor
+	conflicts = low-memory-monitor
+	source = git+https://gitlab.freedesktop.org/hadess/low-memory-monitor.git
+	sha512sums = SKIP
+
+pkgname = low-memory-monitor-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5dc8dd4c68c2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Frederik “Freso” S. Olesen <archlinux@freso.dk>
+_pkgname=low-memory-monitor
+pkgname=${_pkgname}-git
+pkgver=r20.bd5d587
+pkgrel=1
+pkgdesc='Early boot daemon monitoring memory pressure information and invokes OOM if needed'
+arch=('x86_64')
+url="https://gitlab.freedesktop.org/hadess/${_pkgname}"
+license=('GPL3')
+depends=('systemd')
+makedepends=('meson' 'git')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+source=("git+$url.git")
+sha512sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${_pkgname}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$srcdir/${_pkgname}"
+	meson --prefix /usr --buildtype=plain ./ build
+	ninja -C build
+}
+
+check() {
+	cd "$srcdir/${_pkgname}"
+	ninja -C build test
+}
+
+package() {
+	cd "$srcdir/${_pkgname}"
+	DESTDIR="$pkgdir" ninja -C build install
+}