Initial commit

2 files changed, 88 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9361c007ab43
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = maestral-qt-git
+	pkgdesc = A Qt interface for the Maestral daemon
+	pkgver = 0.6.4.r0.g28c4c50
+	pkgrel = 1
+	url = https://github.com/SamSchott/maestral-qt
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = python
+	makedepends = python-setuptools
+	makedepends = gendesk
+	depends = maestral
+	depends = python
+	depends = python-bugsnag
+	depends = python-click>=7.1.1
+	depends = python-markdown2
+	depends = python-packaging
+	depends = python-pyqt5>=5.9
+	optdepends = gnome-shell-extension-appindicator: Gnome integration
+	provides = maestral-qt
+	conflicts = maestral-qt
+	source = git+https://github.com/SamSchott/maestral-qt
+	md5sums = SKIP
+
+pkgname = maestral-qt-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3a5b319f7838
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Batuhan Baserdem <lastname dot firstname at gmail>
+
+_name=maestral-qt
+
+pkgname="${_name}-git"
+provides=("${_name}")
+conflicts=("${_name}")
+pkgver=0.6.4.r0.g28c4c50
+pkgrel=1
+pkgdesc='A Qt interface for the Maestral daemon'
+arch=('any')
+url="https://github.com/SamSchott/${_name}"
+license=('MIT')
+source=("git+${url}")
+makedepends=('git' 'python' 'python-setuptools' 'gendesk')
+depends=(
+    'maestral'
+    'python'
+    'python-bugsnag'
+    'python-click>=7.1.1'
+    'python-markdown2'
+    'python-packaging'
+    'python-pyqt5>=5.9')
+# maestral:         AUR dependency (git-version maintained by me)
+# python-bugsnag:   AUR dependency (git-version maintained by me)
+# python-markdown2: AUR dependency
+optdepends=('gnome-shell-extension-appindicator: Gnome integration')
+md5sums=('SKIP')
+
+prepare() {
+    gendesk -q -n \
+        --pkgname="${_name}" \
+        --exec="${_name} gui" \
+        --comment="${pkgdesc}" \
+        --categories=Network
+}
+
+pkgver() {
+    cd "${srcdir}/${_name}"
+    git describe --long --tags | sed 's|\([^-]*-g\)|r\1|;s|-|.|g;s|^v||g'
+}
+
+build() {
+    cd "${srcdir}/${_name}"
+    python setup.py build
+}
+
+package() {
+    # Change into the source git directory
+    cd "${srcdir}/${_name}"
+
+    # Run python setup function
+    python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+
+    # Install the licence
+    install -Dm644 "${srcdir}/${_name}/LICENSE.txt" \
+        "${pkgdir}/usr/share/licenses/${_name}/LICENSE"
+
+    # Install the generated desktop file
+    install -Dm644 "${srcdir}/${_name}.desktop" -t \
+        "${pkgdir}/usr/share/applications"
+}