Initial commit

2 files changed, 53 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ed33d278aafa
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = marswm-git
+	pkgdesc = A rusty successor to moonwm
+	pkgver = 0.1.0.r0.g62df0c0
+	pkgrel = 1
+	url = https://github.com/jzbor/marswm
+	arch = x86_64
+	license = custom
+	makedepends = cargo
+	provides = marswm
+	provides = mars-relay
+	conflicts = marswm
+	conflicts = mars-relay
+	source = git+https://github.com/jzbor/marswm
+	sha512sums = SKIP
+
+pkgname = marswm-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e4a39b5a17a4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: jzbor <zborof at posteo dot de>
+pkgname=marswm-git
+pkgver=0.1.0.r0.g62df0c0
+pkgrel=1
+pkgdesc="A rusty successor to moonwm"
+arch=('x86_64')
+url="https://github.com/jzbor/marswm"
+license=('custom')
+depends=()
+makedepends=('cargo')
+provides=(marswm mars-relay)
+conflicts=(marswm mars-relay)
+source=("git+$url")
+sha512sums=('SKIP')
+
+pkgver() {
+	cd "${pkgname%-git}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+    cd "${pkgname%-git}"
+    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+    cd "${pkgname%-git}"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release --all-features
+}
+
+package() {
+    cd "${pkgname%-git}"
+    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${pkgname%-git}"
+    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${pkgname%wm-git}-relay"
+}