Package created

2 files changed, 56 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..edfc8dca7d47
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = mauikit-accounts-git
+	pkgdesc = MauiKit utilities to handle User Accounts
+	pkgver = r10.d9f46d9
+	pkgrel = 1
+	url = https://invent.kde.org/maui/mauikit-accounts
+	arch = x86_64
+	arch = i686
+	arch = arm
+	arch = armv6h
+	arch = armv7h
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	makedepends = extra-cmake-modules
+	depends = mauikit-git
+	depends = ki18n
+	depends = kconfig
+	depends = kcoreaddons
+	provides = mauikit-accounts
+	conflicts = mauikit-accounts
+	source = git+https://invent.kde.org/maui/mauikit-accounts.git
+	sha256sums = SKIP
+
+pkgname = mauikit-accounts-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e44732886282
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >
+
+pkgname=mauikit-accounts-git
+pkgver=r10.d9f46d9
+pkgrel=1
+pkgdesc="MauiKit utilities to handle User Accounts"
+arch=(x86_64 i686 arm armv6h armv7h aarch64)
+url="https://invent.kde.org/maui/mauikit-accounts"
+license=('GPL3')
+depends=('mauikit-git' 'ki18n' 'kconfig' 'kcoreaddons')
+makedepends=('git' 'extra-cmake-modules')
+provides=('mauikit-accounts')
+conflicts=('mauikit-accounts')
+source=("git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RelWithDebInfo -B build -S "${pkgname%-git}"
+  cmake --build build --config RelWithDebInfo
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build --config RelWithDebInfo
+}