Initial commit

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..810d4fc8a25b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = maui-manager-git
+	pkgdesc = Maui Settings Manager
+	pkgver = r7.7ad380e
+	pkgrel = 1
+	url = https://github.com/Nitrux/maui-manager
+	arch = x86_64
+	arch = i686
+	arch = arm
+	arch = armv6h
+	arch = armv7h
+	arch = aarch64
+	groups = maui
+	license = GPL3
+	makedepends = git
+	makedepends = extra-cmake-modules
+	depends = kcoreaddons
+	depends = ki18n
+	depends = mauikit
+	depends = qt5-base
+	depends = qt5-declarative
+	provides = maui-manager
+	conflicts = maui-manager
+	source = git+https://github.com/Nitrux/maui-manager.git
+	sha256sums = SKIP
+
+pkgname = maui-manager-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2374e1a61af5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Wachid Adi Nugroho <wachidadinugroho.maya@gmail.com>
+
+pkgname=maui-manager-git
+_pkgname=${pkgname%-git}
+pkgver=r7.7ad380e
+pkgrel=1
+pkgdesc='Maui Settings Manager'
+url='https://github.com/Nitrux/maui-manager'
+arch=(x86_64 i686 arm armv6h armv7h aarch64)
+license=(GPL3)
+depends=(kcoreaddons
+         ki18n
+         mauikit
+         qt5-base
+         qt5-declarative)
+makedepends=(git extra-cmake-modules)
+groups=(maui)
+provides=($_pkgname)
+conflicts=($_pkgname)
+source=(git+$url.git)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cmake -B build -S $_pkgname \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}