Ported package mda-lv2-svn from AUR 3 archive and converted it to mda-lv2-git

3 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1b5f747f23fd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+# Generated by mksrcinfo v8
+# Sun Feb  7 15:23:35 UTC 2016
+pkgbase = mda-lv2-git
+	pkgdesc = A port of the MDA VST plugins to the LV2 format
+	pkgver = 1.2.2.r177.c6cbb4e
+	pkgrel = 1
+	url = http://drobilla.net/software/mda-lv2/
+	arch = i686
+	arch = x86_64
+	groups = lv2-plugins
+	license = GPL2
+	makedepends = git
+	makedepends = python
+	depends = lv2
+	provides = mda-lv2
+	conflicts = mda-lv2
+	conflicts = mda-lv2-svn
+	source = mda-lv2::git+http://git.drobilla.net/mda.lv2.git
+	md5sums = SKIP
+
+pkgname = mda-lv2-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..a5c19ce5e07c
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,6 @@
+pkg/
+src/
+mda-lv2/
+mda-lv2-git-*.tar.xz
+mda-lv2-git-*.src.tar.gz
+.AURINFO
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e8115510c07c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
+
+_pkgname=mda-lv2
+pkgname="${_pkgname}-git"
+pkgver=1.2.2.r177.c6cbb4e
+pkgrel=1
+pkgdesc="A port of the MDA VST plugins to the LV2 format"
+arch=("i686" "x86_64")
+url="http://drobilla.net/software/mda-lv2/"
+license=("GPL2")
+groups=('lv2-plugins')
+depends=('lv2')
+makedepends=('git' 'python')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}" "${_pkgname}-svn")
+source=("${_pkgname}::git+http://git.drobilla.net/mda.lv2.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+
+  local ver=`grep "^MDA_VERSION" wscript | cut -d "'" -f 2`
+  echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+
+  python ./waf configure --prefix="/usr"
+  python ./waf build
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}"
+
+  python ./waf install --destdir="${pkgdir}"
+}
+
+# vim:set ts=2 sw=2 et: