Initial upload

2 files changed, 60 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3ad5cf06d747
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = mediawiki-skin-tweeki-git
+	pkgdesc = MediaWiki skin based on Twitter's Bootstrap
+	pkgver = 1.1.0.r23.g9441ca6
+	pkgrel = 1
+	url = https://www.mediawiki.org/wiki/Skin:Tweeki
+	arch = any
+	license = GPL2
+	makedepends = git
+	depends = mediawiki
+	provides = mediawiki-skin-tweeki
+	conflicts = mediawiki-skin-tweeki
+	source = git+https://github.com/thaider/Tweeki.git
+	sha512sums = SKIP
+
+pkgname = mediawiki-skin-tweeki-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..737395ca6fd2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Einhard Leichtfuß <alguien@respiranto.de>
+
+_skinname=Tweeki
+_skinname_lowercase="${_skinname,,}"
+_pkgname_base="mediawiki-skin-${_skinname_lowercase}"
+
+pkgname="${_pkgname_base}-git"
+pkgver=1.1.0.r23.g9441ca6
+pkgrel=1
+pkgdesc="MediaWiki skin based on Twitter's Bootstrap"
+arch=('any')
+url="https://www.mediawiki.org/wiki/Skin:${_skinname}"
+license=('GPL2')
+depends=('mediawiki')
+makedepends=('git')
+provides=("$_pkgname_base")
+conflicts=("$_pkgname_base")
+source=("git+https://github.com/thaider/Tweeki.git")
+sha512sums=('SKIP')
+
+prepare()
+{
+	cd "$_skinname"
+
+	# Avoid escaping of the HTML displaying a pencil icon next to section
+	# headings.
+	# See also https://github.com/thaider/Tweeki/issues/154.
+	sed -Ei 's/(^\s*\$text) = (\$icon .* \$text)\;/\1 = new HTMLArmor( \2 )\;/' \
+		includes/Hooks.php
+}
+
+pkgver()
+{
+	cd "$_skinname"
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package()
+{
+	local skin_dir="/usr/share/webapps/mediawiki/skins/${_skinname}"
+
+	install -d -m755 "${pkgdir}${skin_dir}"
+	cp -a "$_skinname"/* "${pkgdir}${skin_dir}/"
+}