Initial upload: mfek-glif-git 1.0a.r16.g561930f-1

2 files changed, 56 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5ed677bf7fad
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = mfek-glif-git
+	pkgdesc = A stand-alone glyph viewer and editor (from Modular Font Editor K)
+	pkgver = 1.0a.r16.g561930f
+	pkgrel = 1
+	url = https://github.com/MFEK/glif
+	arch = x86_64
+	license = Apache
+	makedepends = git
+	makedepends = rust-nightly
+	depends = gtk3
+	depends = libxcb
+	provides = mfek-glif=1.0a.r16.g561930f
+	conflicts = mfek-glif
+	source = mfek-glif-git::git+https://github.com/MFEK/glif.git
+	sha256sums = SKIP
+
+pkgname = mfek-glif-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2fc54f8ee6df
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+
+_pkgname=glif
+pkgname=mfek-$_pkgname-git
+pkgver=1.0a.r16.g561930f
+pkgrel=1
+pkgdesc='A stand-alone glyph viewer and editor (from Modular Font Editor K)'
+arch=(x86_64)
+url="https://github.com/MFEK/$_pkgname"
+license=(Apache)
+depends=(gtk3 libxcb)
+makedepends=(git rust-nightly)
+provides=("${pkgname%-git}=$pkgver")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags --abbrev=7 --tags HEAD |
+        sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+    cd "$pkgname"
+    cargo fetch --locked
+}
+
+build() {
+    cd "$pkgname"
+    cargo build --offline --release --all-features
+}
+
+package() {
+    cd "$pkgname"
+    install -Dm755 target/release/MFEK$_pkgname "$pkgdir/usr/bin/${pkgname%-git}"
+    install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}