Upgrading to 0.0.5. Updating maintainer info. Building with system waf. Running lv2lint and sord_validate in check().

1 files changed, 32 insertions, 10 deletions

diff --git a/PKGBUILD b/PKGBUILD
index c46f83975324..7a65bb00151f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,25 +1,47 @@
-# Maintainer: David Runge <dave@sleepmap.de>
+# Maintainer: David Runge <dvzrv@archlinux.org>
 pkgname=midimsg-lv2
-pkgver=0.0.4
+pkgver=0.0.5
 pkgrel=1
 pkgdesc="A collection of basic LV2 plugins to translate midi messages to usable values"
 arch=('x86_64')
-url="https://objectivewave.wordpress.com/midimsg-lv2/"
+url="https://github.com/blablack/midimsg-lv2"
 license=('GPL3')
 groups=('lv2-plugins' 'pro-audio')
-depends=('gcc-libs')
-makedepends=('lv2' 'python2')
-source=("$pkgname-$pkgver.tar.gz::https://github.com/blablack/${pkgname}/archive/${pkgver}.tar.gz")
-sha512sums=('d9d563f77941f8741928204f8940621f638a24f1bb2c13f116f0695a056a8792b486a7385f98bb0d93e7fede4c2d719c405b843a25c0782560d7b45a5cf4d404')
+depends=('gcc-libs' 'glibc')
+makedepends=('lv2' 'waf')
+checkdepends=('lv2lint' 'sord')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/blablack/${pkgname}/archive/v${pkgver}.tar.gz")
+sha512sums=('e2977dfda904e48e87fdfb416b700efae578ceeb81cbcf1ad1a40a3dc0a80e8b92a98d846d25deb367f1763a285816a99ec3db399137f5faa5b53c9bcc1646cb')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  mkdir -vp tools
+  touch __init__.py
+  cp -v waflib/extras/{autowaf,lv2}.py tools
+  # modify wscript to use current scripts and fix version
+  sed -e 's/waflib.extras/tools/' \
+      -e "s/load('lv2'/load('lv2', tooldir='tools'/" \
+      -i wscript
+  rm -rv waflib
+}
 
 build() {
   cd "$pkgname-$pkgver"
-  python2 ./waf configure --prefix=/usr
-  python2 ./waf
+  waf configure --prefix=/usr
+  waf build -vv
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  # the plugin names don't adhere to their project name, so for lv2lint tests they have to be copied in place
+  cp -av "build/${pkgname//-/.}" "build/${pkgname}"
+  LV2_PATH="${PWD}/build" lv2lint "http://github.com/blablack/midimsg-lv2/" || echo "Known to fail: https://github.com/blablack/midimsg-lv2/issues/1"
+  rm -rv "build/${pkgname}"
+  sord_validate "${PWD}/build/${pkgname//-/.}/"*.ttl || echo "Known to fail: https://github.com/blablack/midimsg-lv2/issues/1"
 }
 
 package() {
   cd "$pkgname-$pkgver"
-  python2 ./waf install --destdir="$pkgdir/"
+  waf install --destdir="$pkgdir/"
   install -vDm 644 {THANKS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
 }