Submit mindforger to AUR

2 files changed, 73 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..2e1e4a8e249c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = mindforger-src
+	pkgdesc = Thinking notebook and Markdown IDE. Search, browse, view and edit your Markdown files. Get as much as possible from knowledge in your remarks. (Build from source.)
+	pkgver = 1.48.2
+	pkgrel = 1
+	url = https://github.com/dvorka/mindforger
+	arch = any
+	license = GPL-2.0
+	makedepends = git
+	depends = hicolor-icon-theme
+	depends = qt5-base
+	depends = qt5-svg
+	depends = qt5-webkit
+	depends = zlib
+	optdepends = dropbox: Dropbox syncing
+	provides = mindforger
+	conflicts = mindforger
+	source = mindforger::git+https://github.com/dvorka/mindforger.git#tag=1.48.2
+	source = mindforger-repository::git+https://github.com/dvorka/mindforger-repository.git#commit=120b883
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = mindforger-src
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2e6f11b0cce9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Maxim Mikityanskiy <maxtram95@gmail.com>
+
+_pkgname=mindforger
+pkgname=$_pkgname-src
+pkgver=1.48.2
+pkgrel=1
+pkgdesc="Thinking notebook and Markdown IDE. Search, browse, view and edit your Markdown files. Get as much as possible from knowledge in your remarks. (Build from source.)"
+arch=('any')
+url="https://github.com/dvorka/mindforger"
+license=('GPL-2.0')
+depends=('hicolor-icon-theme' 'qt5-base' 'qt5-svg' 'qt5-webkit' 'zlib')
+optdepends=('dropbox: Dropbox syncing')
+makedepends=('git')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=(
+	"$_pkgname::git+https://github.com/dvorka/$_pkgname.git#tag=$pkgver"
+	"$_pkgname-repository::git+https://github.com/dvorka/$_pkgname-repository.git#commit=120b883"
+)
+sha256sums=('SKIP' 'SKIP')
+
+prepare() {
+	cd "$srcdir/$_pkgname"
+	git submodule update --init --recursive
+}
+
+build() {
+	cd "$srcdir/$_pkgname"
+
+	cd deps/discount
+	./configure.sh
+	make
+	cd -
+
+	qmake-qt5 -r CONFIG+=mfnoccache mindforger.pro
+	make V=1 VERBOSE=1
+}
+
+package() {
+	cd "$srcdir/$_pkgname"
+	make INSTALL_ROOT="$pkgdir" install
+
+	# No need to install a package-specific static lib.
+	rm "$pkgdir/usr/lib/libdiscount.a"
+
+	cd "$srcdir/$_pkgname-repository"
+	mkdir -p "$pkgdir/usr/share/doc/mindforger/"
+	# Copy visible files only (excludes .git).
+	cp -dr * "$pkgdir/usr/share/doc/mindforger/"
+}