summarylogtreecommitdiffstats
diff options
context:
space:
mode:
authorMartchus2015-12-26 00:07:26 +0100
committerMartchus2015-12-26 00:07:26 +0100
commit2af4e2409e12fd168eed3a2531708db2bf4d7a65 (patch)
treeb481ceafff613028d56bdc3d49802edad59c72e1
downloadaur-2af4e2409e12fd168eed3a2531708db2bf4d7a65.tar.gz
initial import
-rw-r--r--.SRCINFO28
-rw-r--r--PKGBUILD66
2 files changed, 94 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..cb70a590ca5
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,28 @@
+# Generated by mksrcinfo v8
+# Fri Dec 25 23:06:31 UTC 2015
+pkgbase = mingw-w64-geany
+ pkgdesc = Fast and lightweight IDE (mingw-w64)
+ pkgver = 1.26
+ pkgrel = 1
+ url = http://www.geany.org/
+ arch = any
+ license = GPL
+ makedepends = perl-xml-parser
+ makedepends = setconf
+ makedepends = intltool
+ makedepends = mingw-w64-gcc
+ makedepends = mingw-w64-configure
+ makedepends = mingw-w64-binutils
+ depends = mingw-w64-crt
+ depends = mingw-w64-gtk2
+ optdepends = mingw-w64-geany-plugins: various extra features
+ optdepends = mingw-w64-python2
+ options = !buildflags
+ options = staticlibs
+ options = !strip
+ options = !emptydirs
+ source = http://download.geany.org/geany-1.26.tar.bz2
+ sha256sums = e38530e87c577e1e9806be3b40e08fb9ee321eb1abc6361ddacdad89c825f90d
+
+pkgname = mingw-w64-geany
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..efe7fa90249
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,66 @@
+# Maintainer: Martchus <martchus@gmx.net>
+# Contributor: Alexander Rødseth <rodseth@gmail.com>
+# Contributor: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.ro>
+# Contributor: William Rea <sillywilly@gmail.com>
+# Contributor: Allan McRae <mcrae_allan@hotmail.com>
+
+_name=geany
+pkgname=mingw-w64-geany
+pkgver=1.26
+pkgrel=1
+pkgdesc='Fast and lightweight IDE (mingw-w64)'
+arch=('any')
+url='http://www.geany.org/'
+license=('GPL')
+depends=('mingw-w64-crt' 'mingw-w64-gtk2')
+makedepends=('perl-xml-parser' 'setconf' 'intltool' 'mingw-w64-gcc' 'mingw-w64-configure' 'mingw-w64-binutils')
+optdepends=('mingw-w64-geany-plugins: various extra features'
+ 'mingw-w64-python2')
+source=("http://download.geany.org/${_name}-$pkgver.tar.bz2")
+sha256sums=('e38530e87c577e1e9806be3b40e08fb9ee321eb1abc6361ddacdad89c825f90d')
+options=(!buildflags staticlibs !strip !emptydirs)
+
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+prepare() {
+ cd "${_name}-$pkgver"
+
+ # Python2 fix
+ sed -i '0,/on/s//on2/' data/templates/files/main.py
+
+ # Syntax highlighting for PKGBUILD files
+ sed -i 's/Sh=/Sh=PKGBUILD;/' data/filetype_extensions.conf
+}
+
+build() {
+ cd "${_name}-$pkgver"
+ for _arch in ${_architectures}; do
+ mkdir -p "build-${_arch}"
+ pushd "build-${_arch}"
+ ${_arch}-configure \
+ --exec-prefix=/usr/${_arch} \
+ --sysconfdir=/etc \
+ --prefix=/usr/${_arch}
+ make
+ popd
+ done
+}
+
+package() {
+ cd "${_name}-$pkgver"
+ for _arch in ${_architectures}; do
+ pushd "build-${_arch}"
+ make DESTDIR="$pkgdir" install
+ ${_arch}-strip -g "${pkgdir}/usr/${_arch}/lib/"*.a
+ ${_arch}-strip -g "${pkgdir}/usr/${_arch}/lib/geany/"*.a
+ ${_arch}-strip --strip-unneeded "${pkgdir}/usr/${_arch}/lib/geany/"*.dll
+ ${_arch}-strip --strip-all "${pkgdir}/usr/${_arch}/bin/"*.exe
+ ${_arch}-strip --strip-unneeded "${pkgdir}/usr/${_arch}/bin/"*.dll
+ rm "${pkgdir}/usr/${_arch}/"*.txt
+ popd
+ done
+}
+
+# getver: -u 7 geany.org/Documentation/ReleaseNotes
+# vim:set ts=2 sw=2 et: