Initial import

2 files changed, 73 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..75c7b60c2ca1
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+# Generated by mksrcinfo v8
+# Sat Jan 27 14:27:11 UTC 2018
+pkgbase = mingw-w64-reflective-rapidjson
+	pkgdesc = Code generator for serializing/deserializing C++ objects to/from JSON using Clang and RapidJSON (mingw-w64)
+	pkgver = 0.0.2
+	pkgrel = 1
+	url = https://github.com/Martchus/reflective-rapidjson
+	arch = any
+	license = GPL
+	makedepends = mingw-w64-gcc
+	makedepends = mingw-w64-cmake
+	depends = mingw-w64-crt
+	depends = mingw-w64-c++utilities
+	depends = mingw-w64-rapidjson
+	depends = reflective-rapidjson
+	optdepends = reflective-rapidjson-doc: API documentation
+	options = !buildflags
+	options = staticlibs
+	options = !strip
+	options = !emptydirs
+	source = reflective-rapidjson-0.0.2.tar.gz::https://github.com/Martchus/reflective-rapidjson/archive/v0.0.2.tar.gz
+	sha256sums = 7a41deebf594e845a02f9f037a00f8cc19af65ba2fd7c364a0e5c3702e324506
+
+pkgname = mingw-w64-reflective-rapidjson
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a6bbfc7d73d9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+_reponame=reflective-rapidjson
+pkgname=mingw-w64-reflective-rapidjson
+_name=${pkgname#mingw-w64-}
+pkgver=0.0.2
+pkgrel=1
+arch=('any')
+pkgdesc='Code generator for serializing/deserializing C++ objects to/from JSON using Clang and RapidJSON (mingw-w64)'
+license=('GPL')
+depends=('mingw-w64-crt' 'mingw-w64-c++utilities' 'mingw-w64-rapidjson' 'reflective-rapidjson')
+optdepends=("mingw-w64-boost: use Boost.Hana instead of code generator")
+optdepends=("$_name-doc: API documentation")
+makedepends=('mingw-w64-gcc' 'mingw-w64-cmake')
+url="https://github.com/Martchus/${_reponame}"
+source=("${_name}-${pkgver}.tar.gz::https://github.com/Martchus/${_reponame}/archive/v${pkgver}.tar.gz")
+sha256sums=('7a41deebf594e845a02f9f037a00f8cc19af65ba2fd7c364a0e5c3702e324506')
+options=(!buildflags staticlibs !strip !emptydirs)
+_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
+[[ $NO_STATIC_LIBS ]] || _configurations='-DENABLE_STATIC_LIBS:BOOL=ON'
+[[ $NO_SHARED_LIBS ]] && _configurations+=' -DDISABLE_SHARED_LIBS:BOOL=ON'
+
+build() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
+  for _arch in ${_architectures}; do
+    mkdir -p "build-${_arch}" && pushd "build-${_arch}"
+    # disable building the code generator since it is not useful for cross-compilation
+    ${_arch}-cmake -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX="/usr/${_arch}" \
+        -DNO_GENERATOR=ON \
+        ${_configurations} \
+        ../
+    make
+    popd
+  done
+}
+
+package() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
+  for _arch in ${_architectures}; do
+    mkdir -p "build-${_arch}" && pushd "build-${_arch}"
+    make DESTDIR="${pkgdir}" install-mingw-w64-strip
+    popd
+  done
+}