summarylogtreecommitdiffstats
diff options
context:
space:
mode:
authorRoman Beslik2020-03-14 20:59:48 +0200
committerRoman Beslik2020-03-14 20:59:48 +0200
commit6899afba890aa6eddbb7a06e441a9787e782b74c (patch)
treedf5f39e195dcb572482566040283d55afb4d5d1c
downloadaur-6899afba890aa6eddbb7a06e441a9787e782b74c.tar.gz
initial
-rw-r--r--.SRCINFO65
-rw-r--r--PKGBUILD111
-rw-r--r--mono.binfmt.d1
-rw-r--r--mono.install7
4 files changed, 184 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..85eec159537
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,65 @@
+pkgbase = mono-alt-csc
+ pkgdesc = Free implementation of the .NET platform including runtime and compiler. "csc" is renamed to "mono-csc".
+ pkgver = 6.4.0.198
+ pkgrel = 1
+ url = https://www.mono-project.com/
+ install = mono.install
+ arch = x86_64
+ license = GPL
+ license = LGPL2.1
+ license = MPL
+ makedepends = cmake
+ makedepends = git
+ depends = zlib
+ depends = libgdiplus>=4.2
+ depends = sh
+ depends = python
+ depends = ca-certificates
+ provides = monodoc
+ provides = mono
+ conflicts = monodoc
+ conflicts = mono
+ replaces = mono
+ source = mono-alt-csc::git+https://github.com/mono/mono#commit=fe64a4765e6d1dbb41d5c86708fcb02aa519247a
+ source = git+https://github.com/mono/aspnetwebstack
+ source = git+https://github.com/mono/Newtonsoft.Json
+ source = git+https://github.com/mono/cecil
+ source = git+https://github.com/mono/rx
+ source = git+https://github.com/mono/ikvm-fork
+ source = git+https://github.com/mono/ikdasm
+ source = git+https://github.com/mono/reference-assemblies
+ source = git+https://github.com/mono/NUnitLite
+ source = git+https://github.com/mono/NuGet.BuildTasks
+ source = git+https://github.com/mono/boringssl
+ source = git+https://github.com/mono/corefx
+ source = git+https://github.com/mono/bockbuild
+ source = git+https://github.com/mono/linker
+ source = git+https://github.com/mono/roslyn-binaries
+ source = git+https://github.com/mono/corert
+ source = git+https://github.com/mono/xunit-binaries
+ source = git+https://github.com/mono/api-doc-tools
+ source = git+https://github.com/mono/api-snapshot
+ source = mono.binfmt.d
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = SKIP
+ sha256sums = 9a657fc153ef4ce23bf5fc369a26bf4a124e9304bde3744d04c583c54ca47425
+
+pkgname = mono-alt-csc
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..3ab86020164
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,111 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Giancarlo Razzolinit <grazzolini@gmail.com>
+# Contributor: Daniel Isenmann <daniel@archlinux.org>
+# Contributor: Brice Carpentier <brice@dlfp.org>
+
+pkgname=mono-alt-csc
+_gitcommit=fe64a4765e6d1dbb41d5c86708fcb02aa519247a
+pkgver=6.4.0.198
+pkgrel=1
+pkgdesc='Free implementation of the .NET platform including runtime and compiler. "csc" is renamed to "mono-csc".'
+url='https://www.mono-project.com/'
+arch=('x86_64')
+license=('GPL' 'LGPL2.1' 'MPL')
+depends=('zlib' 'libgdiplus>=4.2' 'sh' 'python' 'ca-certificates')
+makedepends=('cmake' 'git')
+provides=('monodoc' 'mono')
+conflicts=('monodoc' 'mono')
+replaces=('mono')
+install=mono.install
+source=(${pkgname}::"git+https://github.com/mono/mono#commit=${_gitcommit}"
+ git+https://github.com/mono/aspnetwebstack
+ git+https://github.com/mono/Newtonsoft.Json
+ git+https://github.com/mono/cecil
+ git+https://github.com/mono/rx
+ git+https://github.com/mono/ikvm-fork
+ git+https://github.com/mono/ikdasm
+ git+https://github.com/mono/reference-assemblies
+ git+https://github.com/mono/NUnitLite
+ git+https://github.com/mono/NuGet.BuildTasks
+ git+https://github.com/mono/boringssl
+ git+https://github.com/mono/corefx
+ git+https://github.com/mono/bockbuild
+ git+https://github.com/mono/linker
+ git+https://github.com/mono/roslyn-binaries
+ git+https://github.com/mono/corert
+ git+https://github.com/mono/xunit-binaries
+ git+https://github.com/mono/api-doc-tools
+ git+https://github.com/mono/api-snapshot
+ mono.binfmt.d)
+sha256sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ '9a657fc153ef4ce23bf5fc369a26bf4a124e9304bde3744d04c583c54ca47425')
+
+pkgver() {
+ cd ${pkgname}
+ git describe --tags | sed 's/^v//;s/^mono-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd ${pkgname}
+ git submodule init
+ git config submodule."external/aspnetwebstack".url "${srcdir}/aspnetwebstack"
+ git config submodule."external/Newtonsoft.Json".url "${srcdir}/Newtonsoft.Json"
+ git config submodule."external/cecil".url "${srcdir}/cecil"
+ git config submodule."external/rx".url "${srcdir}/rx"
+ git config submodule."external/ikvm".url "${srcdir}/ikvm-fork"
+ git config submodule."external/ikdasm".url "${srcdir}/ikdasm"
+ git config submodule."external/reference-assemblies".url "${srcdir}/reference-assemblies"
+ git config submodule."external/nunit-lite".url "${srcdir}/NUnitLite"
+ git config submodule."external/nuget-buildtasks".url "${srcdir}/NuGet.BuildTasks"
+ git config submodule."external/cecil-legacy".url "${srcdir}/cecil"
+ git config submodule."external/boringssl".url "${srcdir}/boringssl"
+ git config submodule."external/corefx".url "${srcdir}/corefx"
+ git config submodule."external/bockbuild".url "${srcdir}/bockbuild"
+ git config submodule."external/linker".url "${srcdir}/linker"
+ git config submodule."external/roslyn-binaries".url "${srcdir}/roslyn-binaries"
+ git config submodule."external/corert".url "${srcdir}/corert"
+ git config submodule."external/xunit-binaries".url "${srcdir}/xunit-binaries"
+ git config submodule."external/api-doc-tools".url "${srcdir}/api-doc-tools"
+ git config submodule."external/api-snapshot".url "${srcdir}/api-snapshot"
+ git submodule update --recursive
+}
+
+build() {
+ cd ${pkgname}
+ ./autogen.sh \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --bindir=/usr/bin \
+ --sbindir=/usr/bin \
+ --with-mcs-docs=no
+ make
+ make -C mcs/jay
+}
+
+package() {
+ cd ${pkgname}
+ make DESTDIR="${pkgdir}" install
+ make -C mcs/jay DESTDIR="${pkgdir}" prefix=/usr INSTALL=../../install-sh install
+ mv "${pkgdir}/usr/bin/csc" "${pkgdir}/usr/bin/mono-csc"
+ install -Dm 644 "${srcdir}/mono.binfmt.d" "${pkgdir}/usr/lib/binfmt.d/mono.conf"
+}
+
+# vim: ts=2 sw=2 et:
diff --git a/mono.binfmt.d b/mono.binfmt.d
new file mode 100644
index 00000000000..3075b0dc5e4
--- /dev/null
+++ b/mono.binfmt.d
@@ -0,0 +1 @@
+:CLR:M::MZ::/usr/bin/mono:
diff --git a/mono.install b/mono.install
new file mode 100644
index 00000000000..cd0363b84a9
--- /dev/null
+++ b/mono.install
@@ -0,0 +1,7 @@
+post_install() {
+ post_upgrade
+}
+
+post_upgrade() {
+ cert-sync /etc/ssl/certs/ca-certificates.crt
+}