add musializer-git

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5dea59a4fc60
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = musializer-git
+	pkgdesc = Music Visualizer
+	pkgver = r256.0cc08f5
+	pkgrel = 1
+	url = https://github.com/tsoding/musializer
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = libx11
+	makedepends = libxrandr
+	makedepends = libxinerama
+	makedepends = xorg-xinput
+	depends = ffmpeg
+	source = git+https://github.com/tsoding/musializer
+	sha256sums = SKIP
+
+pkgname = musializer-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d46ee4a7979b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Junxuan Liao <mikeljx at 126 dot com>
+_pkgname=musializer
+pkgname=$_pkgname-git
+pkgver=r256.0cc08f5
+pkgrel=1
+pkgdesc="Music Visualizer"
+arch=('x86_64')
+url="https://github.com/tsoding/musializer"
+license=('MIT')
+depends=('ffmpeg')
+makedepends=(
+    'git'
+    'libx11'
+    'libxrandr'
+    'libxinerama'
+    'xorg-xinput'
+    )
+source=("git+$url")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "${srcdir}/${_pkgname}"
+    sed -i 's/\.\/resources/\/usr\/share\/'$_pkgname'\/&/' src/plug.c src/musializer.c
+}
+
+pkgver() {
+	cd "${srcdir}/${_pkgname}"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}"
+    gcc -o nob nob.c
+    ./nob
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}"
+    install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+    find resources -type f -exec \
+        install -Dm 644 '{}' "${pkgdir}/usr/share/musializer/{}" \;
+    install -Dm 755 ./build/musializer "${pkgdir}"/usr/bin/musializer
+}
+