Initial package upload

3 files changed, 150 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b014811b31dc
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,40 @@
+pkgbase = natron-compositor-git
+	pkgdesc = Open source compositing software
+	pkgver = v2.4.0.r6.g4007f810d
+	pkgrel = 1
+	url = https://natrongithub.github.io/
+	arch = x86_64
+	license = GPL
+	makedepends = boost
+	makedepends = expat
+	makedepends = openmp
+	depends = boost-libs
+	depends = cairo
+	depends = glfw-x11
+	depends = python2-pyside
+	optdepends = openfx-arena: Extra OpenFX plugins for Natron
+	optdepends = openfx-gmic: OpenFX wrapper for the GMIC framework
+	optdepends = openfx-io: Readers/Writers plugins
+	optdepends = openfx-misc: Miscellaneous OpenFX plugins
+	conflicts = natron
+	source = natron::git+https://github.com/NatronGitHub/Natron
+	source = openfx::git+https://github.com/NatronGitHub/openfx
+	source = OpenColorIO-Configs::git+https://github.com/NatronGitHub/OpenColorIO-Configs
+	source = google-breakpad::git+https://github.com/NatronGitHub/google-breakpad
+	source = google-mock::git+https://github.com/NatronGitHub/google-mock
+	source = google-test::git+https://github.com/NatronGitHub/google-test
+	source = SequenceParsing::git+https://github.com/NatronGitHub/SequenceParsing
+	source = tinydir::git+https://github.com/NatronGitHub/tinydir
+	source = config.pri
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = SKIP
+	sha512sums = 48017b7b9cd1854064b9ddffecedef89a4d38070f9a7d2cd506aad481a8061c5cffe5e5c84fc9b0ac5216fc99e093481db367e91ce52cb2a8a66223c4209402a
+
+pkgname = natron-compositor-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4c28cd7a8fb3
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,90 @@
+# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
+# Contributor: Luca Weiss <luca (at) z3ntu (dot) xyz>
+# Contributor: Özgür Sarıer <echo b3pndXJzYXJpZXIxMDExNjAxMTE1QGdtYWlsLmNvbQo= | base64 -d>
+# Contributor: liberodark
+
+pkgname=natron-compositor-git
+pkgver=v2.4.0.r6.g4007f810d
+pkgrel=1
+pkgdesc="Open source compositing software"
+arch=('x86_64')
+url="https://natrongithub.github.io/"
+license=('GPL')
+depends=('boost-libs' 'cairo' 'glfw-x11' 'python2-pyside')
+makedepends=('boost' 'expat' 'openmp')
+optdepends=('openfx-arena: Extra OpenFX plugins for Natron'
+            'openfx-gmic: OpenFX wrapper for the GMIC framework'
+            'openfx-io: Readers/Writers plugins'
+            'openfx-misc: Miscellaneous OpenFX plugins')
+
+_pkgname=${pkgname%%-*}
+_url="https://github.com/NatronGitHub"
+
+conflicts=("${_pkgname}")
+
+source=("${_pkgname}::git+${_url}/${_pkgname^}"
+        "openfx::git+${_url}/openfx"
+        "OpenColorIO-Configs::git+${_url}/OpenColorIO-Configs"
+        "google-breakpad::git+${_url}/google-breakpad"
+        "google-mock::git+${_url}/google-mock"
+        "google-test::git+${_url}/google-test"
+        "SequenceParsing::git+${_url}/SequenceParsing"
+        "tinydir::git+${_url}/tinydir"
+        "config.pri")
+sha512sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            '48017b7b9cd1854064b9ddffecedef89a4d38070f9a7d2cd506aad481a8061c5cffe5e5c84fc9b0ac5216fc99e093481db367e91ce52cb2a8a66223c4209402a')
+
+prepare() {
+  mv -f OpenColorIO-Configs config.pri ${_pkgname}
+
+  cd ${_pkgname}
+  git submodule init
+  git config submodule.libs/google-breakpad.url $srcdir/google-breakpad
+  git config submodule.libs/OpenFX.url $srcdir/openfx
+  git config submodule.libs/SequenceParsing.url $srcdir/SequenceParsing
+  git config submodule.Tests/google-mock.url $srcdir/google-mock
+  git config submodule.Tests/google-test.url $srcdir/google-test
+  git submodule update
+
+  cd libs/SequenceParsing
+  git config submodule.tinydir.url $srcdir/tinydir
+  git submodule update
+}
+
+build() {
+  cd "${_pkgname}"
+
+  [[ -d build ]] && rm -r build; mkdir build; cd build
+
+  qmake-qt4 -r ../Project.pro \
+               PREFIX=/usr \
+               BUILD_USER_NAME="Arch_Linux" \
+               CONFIG+=custombuild \
+               CONFIG+=openmp \
+               DEFINES+=QT_NO_DEBUG_OUTPUT \
+               QMAKE_CFLAGS_RELEASE="${CFLAGS}" \
+               QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
+               QMAKE_LFLAGS_RELEASE="${LDFLAGS}"
+
+  make
+}
+
+package() {
+  cd "${_pkgname}/build"
+  make INSTALL_ROOT="${pkgdir}" install
+  
+  install -d "${pkgdir}/usr/share/Natron/Plugins/"
+  cp -r "../Gui/Resources/PyPlugs" \
+        "${pkgdir}/usr/share/Natron/Plugins/"
+
+  install -d "${pkgdir}/etc/profile.d"
+  echo -e "export FONTCONFIG_PATH=/etc/fonts\n" > "${pkgdir}/etc/profile.d/${pkgname%-*}.sh"
+  echo -e "setenv FONTCONFIG_PATH /etc/fonts\n" > "${pkgdir}/etc/profile.d/${pkgname%-*}.csh"
+}
diff --git a/config.pri b/config.pri
new file mode 100644
index 000000000000..5448ccb497ea
--- /dev/null
+++ b/config.pri
@@ -0,0 +1,20 @@
+boost: LIBS += -lboost_serialization
+expat: LIBS += -lexpat
+expat: PKGCONFIG -= expat
+cairo {
+        PKGCONFIG += cairo
+        LIBS -=  $$system(pkg-config --variable=libdir cairo)/libcairo.a
+}
+pyside {
+        PKGCONFIG -= pyside
+        INCLUDEPATH += $$system(pkg-config --variable=includedir pyside-py2)
+        INCLUDEPATH += $$system(pkg-config --variable=includedir pyside-py2)/QtCore
+        INCLUDEPATH += $$system(pkg-config --variable=includedir pyside-py2)/QtGui
+        INCLUDEPATH += $$system(pkg-config --variable=includedir QtGui)
+        LIBS += -lpyside-python2.7
+}
+shiboken {
+        PKGCONFIG -= shiboken
+        INCLUDEPATH += $$system(pkg-config --variable=includedir shiboken-py2)
+        LIBS += -lshiboken-python2.7
+}