neomutt-autocrypt-20191111-1

3 files changed, 99 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..8205ca3e3533
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = neomutt-autocrypt
+	pkgdesc = A version of neomutt with added autocrypt
+	pkgver = 20191111
+	pkgrel = 1
+	url = https://neomutt.org/
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = gnupg
+	makedepends = libxslt
+	makedepends = docbook-xsl
+	makedepends = w3m
+	depends = glibc
+	depends = gpgme
+	depends = lua
+	depends = notmuch-runtime
+	depends = krb5
+	depends = openssl
+	depends = libsasl
+	depends = ncurses
+	depends = libidn2
+	depends = lmdb
+	depends = gdbm
+	depends = kyotocabinet
+	depends = sqlite
+	optdepends = python: keybase.py
+	provides = neomutt
+	conflicts = neomutt
+	source = neomutt-autocrypt-20191111.tar.gz::https://github.com/neomutt/neomutt/archive/20191111.tar.gz
+	sha256sums = 29b9e9d7293157a8575808eb2ceb62ffb2f31be206405abc64fc37a4425e36f4
+
+pkgname = neomutt-autocrypt
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f613c3bff1de
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
+# Contributor: Alad Wenter <alad@archlinux.org>
+# Contributor: Jelle van der Waa <jelle@vdwaa.nl>
+# Contributor: Chris Salzberg <chris@dejimata.com>
+# Contributor: Leonidas Spyropoulos <artafinde@gmail.com>
+pkgname=neomutt-autocrypt
+_srcname=neomutt
+# This package should mirror community/neomutt,
+# except for added autocrypt
+pkgver=20191111
+pkgrel=1
+pkgdesc='A version of neomutt with added autocrypt'
+url='https://neomutt.org/'
+license=('GPL')
+arch=('x86_64')
+depends=('glibc' 'gpgme' 'lua' 'notmuch-runtime' 'krb5' 'openssl'
+         'libsasl' 'ncurses' 'libidn2' 'lmdb' 'gdbm' 'kyotocabinet'
+	 'sqlite')
+provides=('neomutt')
+conflicts=('neomutt')
+optdepends=('python: keybase.py')
+makedepends=('git' 'gnupg' 'libxslt' 'docbook-xsl' 'w3m')
+_github='https://github.com/neomutt/neomutt'
+source=("$pkgname-$pkgver.tar.gz::$_github/archive/$pkgver.tar.gz")
+sha256sums=('29b9e9d7293157a8575808eb2ceb62ffb2f31be206405abc64fc37a4425e36f4')
+
+build() {
+    cd "$_srcname-$pkgver"
+    ./configure \
+        --prefix=/usr \
+        --sysconfdir=/etc \
+        --libexecdir=/usr/lib \
+        --gpgme \
+        --enable-lua \
+        --notmuch \
+        --gss \
+        --ssl \
+        --sasl \
+        --with-ui=ncurses \
+        --with-idn2=/usr \
+        --idn=0 \
+        --idn2=1 \
+        --lmdb \
+        --kyotocabinet \
+        --gdbm \
+	--enable-autocrypt \
+	--sqlite
+    make
+}
+
+package() {
+    cd "$_srcname-$pkgver"
+    make DESTDIR="$pkgdir" install
+}
+
+# eof
diff --git a/README b/README
new file mode 100644
index 000000000000..2f5d1d40f0ab
--- /dev/null
+++ b/README
@@ -0,0 +1,10 @@
+# neomutt-autocrypt
+
+This package is a clone of community/neomutt with autocrypt enabled.
+
+Please see https://autocrypt.org/> to learn more about autocrypt.
+
+Please see https://neomutt.org/guide/autocryptdoc.html to learn how
+to enable and use autocrypt in neomutt.
+
+// Klaus