Clean up PKGBUILD

2 files changed, 26 insertions, 11 deletions

diff --git a/.SRCINFO b/.SRCINFO
index e3990efb587a..7f793d4fdba0 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,12 +1,13 @@
 pkgbase = nodejs-mapscii
 	pkgdesc = Map+Ascii -> MapSCII! Console Map Viewer.
 	pkgver = 0.3.1
-	pkgrel = 2
+	pkgrel = 3
 	url = https://github.com/rastapasta/mapscii#readme
 	arch = any
 	license = MIT
+	makedepends = npm
+	makedepends = jq
 	depends = nodejs
-	depends = npm
 	noextract = mapscii-0.3.1.tgz
 	source = https://registry.npmjs.org/mapscii/-/mapscii-0.3.1.tgz
 	sha1sums = fecb9e96de9408effa8819cf83e5a5d379324198
diff --git a/PKGBUILD b/PKGBUILD
index 2f0caf795147..4c8c44b2058e 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,24 +1,38 @@
 _npmname=mapscii
 _npmver=0.3.1
-pkgname=nodejs-mapscii # All lowercase
+pkgname=nodejs-mapscii
 pkgver=0.3.1
-pkgrel=2
+pkgrel=3
 pkgdesc="Map+Ascii -> MapSCII! Console Map Viewer."
 arch=(any)
 url="https://github.com/rastapasta/mapscii#readme"
 license=(MIT)
-depends=('nodejs' 'npm')
-optdepends=()
+depends=('nodejs')
+makedepends=('npm' 'jq')
 source=(https://registry.npmjs.org/$_npmname/-/$_npmname-$_npmver.tgz)
 noextract=($_npmname-$_npmver.tgz)
 sha1sums=(fecb9e96de9408effa8819cf83e5a5d379324198)
 
 package() {
-  cd $srcdir
-  local _npmdir="$pkgdir/usr/lib/node_modules/"
-  mkdir -p $_npmdir
-  cd $_npmdir
-  npm install -g --prefix "$pkgdir/usr" $_npmname@$_npmver
+  npm install -g --user root --prefix "$pkgdir/usr" "$srcdir/$_npmname-$pkgver.tgz"
+
+  # Non-deterministic race in npm gives 777 permissions to random directories.
+  # See https://github.com/npm/cli/issues/1103 for details.
+  find "${pkgdir}/usr" -type d -exec chmod 755 {} +
+
+  # npm gives ownership of ALL FILES to build user
+  # https://bugs.archlinux.org/task/63396
+  chown -R root:root "${pkgdir}"
+
+  # Remove references to pkgdir
+  find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
+
+  # Remove references to srcdir
+  local tmppackage="$(mktemp)"
+  local pkgjson="$pkgdir/usr/lib/node_modules/$_npmname/package.json"
+  jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
+  mv "$tmppackage" "$pkgjson"
+  chmod 644 "$pkgjson"
 }
 
 # vim:set ts=2 sw=2 et: