initial import

3 files changed, 91 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..6275e19c9d79
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = non-daw-git
+	pkgdesc = A modular Digital Audio Workstation system - Git version.
+	pkgver = 0.r1795.60059f4
+	pkgrel = 1
+	url = http://non.tuxfamily.org
+	install = non.install
+	arch = i686
+	arch = x86_64
+	groups = multimedia
+	license = GPL
+	makedepends = git
+	makedepends = python
+	makedepends = libxpm
+	depends = jack
+	depends = liblo
+	depends = libsigc++
+	depends = liblrdf
+	depends = hicolor-icon-theme
+	depends = ntk
+	provides = non-timeline
+	provides = non-mixer
+	provides = non-session-manager
+	provides = non-sequencer
+	conflicts = non-daw
+	conflicts = non-timeline
+	conflicts = non-mixer
+	conflicts = non-session-manager
+	conflicts = non-sequencer
+	source = git://git.tuxfamily.org/gitroot/non/non.git
+	md5sums = SKIP
+
+pkgname = non-daw-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6fdb1b687a80
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Lieven Moors <lievenmoors@gmail.com>
+# Contributor: Jonathan E. Brickman <jeb@ponderworthy.com>
+# Contributor: Corey Mwamba <contact.me@coreymwamba.co.uk>
+# Contributor: Anshul Sirur <vixus0@gmail.com>
+
+pkgname=non-daw-git
+_gitname=non
+pkgver=0.r1795.60059f4
+pkgrel=1
+pkgdesc="A modular Digital Audio Workstation system - Git version."
+arch=('i686' 'x86_64')
+url="http://non.tuxfamily.org"
+license=('GPL')
+groups=('multimedia')
+depends=('jack' 'liblo' 'libsigc++' 'liblrdf' 'hicolor-icon-theme' 'ntk')
+makedepends=('git' 'python' 'libxpm')
+provides=('non-timeline' 'non-mixer' 'non-session-manager' 'non-sequencer')
+conflicts=('non-daw' 'non-timeline' 'non-mixer' 'non-session-manager' 'non-sequencer')
+source=('git://git.tuxfamily.org/gitroot/non/non.git')
+md5sums=('SKIP')
+install=non.install
+
+pkgver() {
+  cd "${srcdir}/${_gitname}"
+  printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  ./waf configure --prefix="/usr"
+  ./waf
+}
+
+package(){
+  cd "${srcdir}/${_gitname}"
+  ./waf --destdir="${pkgdir}" install
+  install -m 755 "${srcdir}/non/timeline/bin/import-external-sources" "${pkgdir}/usr/bin"
+  install -m 755 "${srcdir}/non/timeline/bin/remove-unused-sources" "${pkgdir}/usr/bin"
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/non.install b/non.install
new file mode 100644
index 000000000000..51cbfe3a2b00
--- /dev/null
+++ b/non.install
@@ -0,0 +1,17 @@
+## arg 1:  the new package version
+post_install() {
+  xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+## arg 1:  the new package version
+## arg 2:  the old package version
+post_upgrade() {
+  post_install
+}
+
+## arg 1:  the old package version
+post_remove() {
+  post_install
+}
+
+# vim:set ts=2 sw=2 et: