Update source repo; clean up PKGBUILD syntax

2 files changed, 34 insertions, 30 deletions

diff --git a/.SRCINFO b/.SRCINFO
index c9ea1afb5daa..f2208a54465f 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,6 +1,6 @@
 pkgbase = notes.lv2-git
 	pkgdesc = An LV2 plugin to store arbitrary notes and images in your project (git version)
-	pkgver = 0.3.1.r88.d0fed49
+	pkgver = 0.4.0.r52.g76403d0
 	pkgrel = 1
 	url = https://open-music-kontrollers.ch/lv2/notes/
 	arch = x86_64
@@ -18,10 +18,9 @@ pkgbase = notes.lv2-git
 	depends = ttf-fira-code
 	depends = ttf-fira-sans
 	provides = notes.lv2
-	provides = notes.lv2=0.3.1.r88.d0fed49
+	provides = notes.lv2=0.4.0.r52.g76403d0
 	conflicts = notes.lv2
-	source = notes.lv2::git+https://github.com/OpenMusicKontrollers/notes.lv2
+	source = notes.lv2::git+https://git.open-music-kontrollers.ch/~hp/notes.lv2
 	sha512sums = SKIP
 
 pkgname = notes.lv2-git
-
diff --git a/PKGBUILD b/PKGBUILD
index d0c83fe65a78..4802af30ddee 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,46 +1,51 @@
 # Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
 
 _name="notes"
-_pkgname="${_name}.lv2"
-pkgname="${_pkgname}-git"
-pkgver=0.3.1.r88.d0fed49
+_pkgname=$_name.lv2
+pkgname=$_pkgname-git
+pkgver=0.4.0.r52.g76403d0
 pkgrel=1
-pkgdesc="An LV2 plugin to store arbitrary notes and images in your project (git version)"
-arch=('x86_64')
-url="https://open-music-kontrollers.ch/lv2/${_name}/"
+pkgdesc='An LV2 plugin to store arbitrary notes and images in your project (git version)'
+arch=(x86_64)
+url='https://open-music-kontrollers.ch/lv2/notes/'
 license=('Artistic2.0')
-groups=('lv2-plugins' 'pro-audio')
-depends=('fontconfig' 'glew' 'libvterm' 'ttf-fira-code' 'ttf-fira-sans')
-makedepends=('git' 'glu' 'lv2' 'meson')
-checkdepends=('lv2lint')
-provides=("${_pkgname}" "${_pkgname}=${pkgver/\.r.*/}")
-conflicts=("${_pkgname}")
-source=("${_pkgname}::git+https://github.com/OpenMusicKontrollers/${_pkgname}")
+groups=(lv2-plugins pro-audio)
+depends=(fontconfig glew libvterm ttf-fira-code ttf-fira-sans)
+makedepends=(git glu lv2 meson)
+checkdepends=(lv2lint)
+provides=($_pkgname "$_pkgname=${pkgver/\.r.*/}")
+conflicts=($_pkgname)
+source=("$_pkgname::git+https://git.open-music-kontrollers.ch/~hp/$_pkgname")
 sha512sums=('SKIP')
 
 pkgver() {
-  cd "${srcdir}/${_pkgname}"
-  local ver="$(cat VERSION)"
-  echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+  cd $_pkgname
+  (
+    set -o pipefail
+    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+    echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+  )
 }
 
 build() {
-  cd "${srcdir}/${_pkgname}"
-  meson --prefix=/usr build
-  ninja -C build
+  cd $_pkgname
+  arch-meson $_pkgname-build
+  meson compile -C $_pkgname-build
 }
 
 check() {
-  cd "${srcdir}/${_pkgname}"
+  cd $_pkgname
   #lv2lint -s 'pugl*' -Mpack -I "build/" \
   #  "http://open-music-kontrollers.ch/lv2/${_pkgname}#${_plugin}"
-  lv2lint -Mpack -I "build/" \
-    "http://open-music-kontrollers.ch/lv2/${_name}#${_name}"
+  lv2lint -Mpack -I $_pkgname-build \
+    "http://open-music-kontrollers.ch/lv2/$_name#$_name"
 }
 
 package() {
-  cd "${srcdir}/${_pkgname}"
-  DESTDIR="${pkgdir}" ninja -C build install
-  install -vDm 644 {ChangeLog,README.md} \
-    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  cd $_pkgname
+  DESTDIR="${pkgdir}" meson install -C $_pkgname-build
+  install -vDm 644 ChangeLog README.md \
+    -t "$pkgdir"/usr/share/doc/$pkgname
+  install -vDm 644 LICENSES/* \
+    -t "$pkgdir"/usr/share/licenses/$pkgname
 }