Release v2.1.0.r57.g0aa13af

3 files changed, 53 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..70a7a5b8d928
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = notp-git
+	pkgdesc = One Time Password Generator
+	pkgver = v2.1.0.r57.g0aa13af
+	pkgrel = 1
+	url = https://github.com/kondanta/notp
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = git
+	conflicts = notp
+	conflicts = notp-bin
+	source = git+https://github.com/kondanta/notp
+	sha256sums = SKIP
+
+pkgname = notp-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..93f3460e8b63
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+/pkg/
+/src/
+/notp/
+*.tar.xz
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b7d5ed34c03e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+pkgname=notp-git
+pkgver=v2.1.0.r57.g0aa13af
+pkgrel=1
+pkgdesc="One Time Password Generator"
+arch=('x86_64')
+url="https://github.com/kondanta/notp"
+license=('MIT')
+makedepends=('cargo' 'git')
+conflicts=("${pkgname%-git}" "${pkgname%-git}-bin")
+source=("git+${url}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --locked --all-features
+}
+
+check() {
+  cd "${pkgname%-git}"
+  cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+}
\ No newline at end of file