Initial upload: onefetch-git 2.5.0.r108.g6197db5-1

2 files changed, 57 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..52ac9caf3df8
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = onefetch-git
+	pkgdesc = Git repository summary on your terminal (git)
+	pkgver = 2.5.0.r108.g6197db5
+	pkgrel = 1
+	url = https://github.com/o2sh/onefetch
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = git
+	depends = libgit2
+	provides = onefetch
+	conflicts = onefetch
+	conflicts = onefetch-bin
+	source = git+https://github.com/o2sh/onefetch
+	sha512sums = SKIP
+
+pkgname = onefetch-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..39ba41f86d86
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=onefetch-git
+pkgver=2.5.0.r108.g6197db5
+pkgrel=1
+pkgdesc="Git repository summary on your terminal (git)"
+arch=('x86_64')
+url="https://github.com/o2sh/onefetch"
+license=('MIT')
+depends=('libgit2')
+makedepends=('cargo' 'git')
+conflicts=("${pkgname%-git}" "${pkgname%-git}-bin")
+provides=("${pkgname%-git}")
+source=("git+${url}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --locked
+}
+
+check() {
+  cd "${pkgname%-git}"
+  cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 LICENSE.md -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
+  install -Dm 644 "${pkgname%-git}.1" -t "$pkgdir/usr/share/man/man1"
+}