initial commit

2 files changed, 57 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4fcb22b4d27e
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = opendbviewer-git
+	pkgdesc = A simple database explorer for SQLITE, MySQL, PostgreSQL.
+	pkgver = v1.0.2.r14.g6bcbd8d
+	pkgrel = 1
+	url = https://github.com/Jet1oeil/opendbviewer
+	arch = x86_64
+	arch = i686
+	license = GPL3
+	makedepends = cmake
+	makedepends = git
+	makedepends = qt5-tools
+	depends = qt5-base
+	provides = opendbviewer
+	conflicts = opendbviewer
+	source = git://github.com/Jet1oeil/opendbviewer.git
+	md5sums = SKIP
+
+pkgname = opendbviewer-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8c31e5f637c2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: liums <liums at openaliasbox.org>
+pkgname=opendbviewer-git
+pkgver=v1.0.2.r14.g6bcbd8d
+pkgrel=1
+pkgdesc="A simple database explorer for SQLITE, MySQL, PostgreSQL."
+arch=('x86_64' 'i686')
+url="https://github.com/Jet1oeil/opendbviewer"
+license=('GPL3')
+depends=('qt5-base')
+makedepends=('cmake' 'git' 'qt5-tools')
+provides=('opendbviewer')
+conflicts=('opendbviewer')
+source=("git://github.com/Jet1oeil/opendbviewer.git")
+_gitname='opendbviewer'
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$_gitname"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "$_gitname"
+	sed -i -e 's/share\/\${APPLICATION_PACKAGE_NAME}\/doc/share\/doc\/\${APPLICATION_PACKAGE_NAME}/' CMakeLists.txt
+}
+
+build() {
+	mkdir -p "$_gitname/build"
+	cd "$_gitname/build"
+	cmake -DCMAKE_INSTALL_PREFIX=/usr ../
+	make
+}
+
+package() {
+	cd "$_gitname"
+	make -C "build/" DESTDIR="$pkgdir/" install
+	install -Dm644 data/logos/opendbviewer.png "$pkgdir/usr/share/pixmaps/opendbviewer.png"
+}